app-text/evince: Version bump to 42.3

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 123 insertions, 0 deletions

diff --git a/app-text/evince/Manifest b/app-text/evince/Manifest
index fca6ef35f38f..232d75ac5846 100644
--- a/app-text/evince/Manifest
+++ b/app-text/evince/Manifest
@@ -1,3 +1,4 @@
 DIST evince-41.3.tar.xz 2889368 BLAKE2B c6ef9b4c126f938ef8b50aa65d8591e0ce02e7404dd1984bce27e0acce6e62462d42665ad19992cb2fa22afd09d6da49ecdbbb51eb209518d415966824523628 SHA512 b00422ef0fd752e5afacea2db852ad71d8d16514945a9a54c54967cecd2b1f5058b762ec53eb9057b8f583d5e1e3363c2b7ae1f4434fa6637ad45c5217f082cd
 DIST evince-42.1.tar.xz 2850652 BLAKE2B 4fb03270caf1be548a82f9094973e584807c497171cef960f344c14158420e02a0fed6d84dcc8d09d3a7f2e8a68f69ffae36398fe6e747d86e3a63132d5a36d6 SHA512 d8ea086b6530c186ac48d88fa2546cd8abd8a075d79037c1f0bf76e63b28914b04a58af83c96e44e04d625fec674f3989bfd51472cd458be9c903a1a4512d8df
 DIST evince-42.2.tar.xz 2854836 BLAKE2B ed8b9e6117d2d456e59d5fd4aac664b73fb450589a04b04b3ada7f1606781001c5ab75a98d425fdf00409e2f4abad59f6a140f39df4ca6bd82a641caaf944062 SHA512 81e93eb5575169ed1a31fdd321a1d7080b4391ddf1ebf13ce49df5ede8bb5f578094b55b2e1075f0a418ef21e8b73f02b259c2bda44b317ea9f551372ee3b860
+DIST evince-42.3.tar.xz 2856080 BLAKE2B 55711dd1869e9cce783845683093bb621b416de66f1d53f901353f6f66ff97ec80ce45e0d32e346b2b37d18285568d01ee96cfe851b09f893565d277651d837c SHA512 4ec212e90c3fd259a2afe191592c135938766b11c6891297a10dc34152f69bba9350a467c394ec6cacde5bd16ced02d0c38b7a112dd7d676f53b12fd1b29a62e
diff --git a/app-text/evince/evince-42.3.ebuild b/app-text/evince/evince-42.3.ebuild
new file mode 100644
index 000000000000..c8e4f7b17473
--- /dev/null
+++ b/app-text/evince/evince-42.3.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Simple document viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+# subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
+SLOT="0/evd3.4-evv3.3"
+IUSE="cups djvu dvi gstreamer gnome gnome-keyring gtk-doc +introspection nautilus postscript spell tiff xps"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+# atk used in libview
+# bundles unarr
+DEPEND="
+	dev-libs/atk
+	>=dev-libs/glib-2.44.0:2
+	>=gui-libs/libhandy-1.5.0:1=
+	>=dev-libs/libxml2-2.5:2
+	sys-libs/zlib:=
+	>=x11-libs/gdk-pixbuf-2.40:2
+	>=x11-libs/gtk+-3.22.0:3[cups?,introspection?]
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/cairo-1.10:=
+	>=app-text/poppler-22.02.0[cairo]
+	>=app-arch/libarchive-3.6.0
+	djvu? ( >=app-text/djvu-3.5.22:= )
+	dvi? (
+		>=app-text/libspectre-0.2:=
+		dev-libs/kpathsea:=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0 )
+	gnome? ( gnome-base/gnome-desktop:3= )
+	gnome-keyring? ( >=app-crypt/libsecret-0.5 )
+	introspection? ( >=dev-libs/gobject-introspection-1:= )
+	nautilus? ( >=gnome-base/nautilus-3.28.0 )
+	postscript? ( >=app-text/libspectre-0.2:= )
+	spell? ( >=app-text/gspell-1.6.0:= )
+	tiff? ( >=media-libs/tiff-4.0:0= )
+	xps? ( >=app-text/libgxps-0.2.1:= )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gvfs
+	gnome-base/librsvg
+	|| (
+		>=x11-themes/adwaita-icon-theme-2.17.1
+		>=x11-themes/hicolor-icon-theme-0.10
+	)
+"
+BDEPEND="
+	gtk-doc? (
+		>=dev-util/gi-docgen-2021.1
+		app-text/docbook-xml-dtd:4.3
+	)
+	dev-libs/appstream-glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Do not depend on adwaita-icon-theme, bug #326855, #391859
+	# https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
+	sed -i '/adwaita_icon_theme_dep/d' meson.build shell/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddevelopment=false
+		-Dplatform=gnome
+
+		-Dviewer=true
+		-Dpreviewer=true
+		-Dthumbnailer=true
+		$(meson_use nautilus)
+
+		-Dcomics=enabled
+		$(meson_feature djvu)
+		$(meson_feature dvi)
+		-Dpdf=enabled
+		$(meson_feature postscript ps)
+		$(meson_feature tiff)
+		$(meson_feature xps)
+
+		$(meson_use gtk-doc gtk_doc)
+		-Duser_doc=true
+		$(meson_use introspection)
+		-Ddbus=true
+		$(meson_feature gnome-keyring keyring)
+		$(meson_feature cups gtk_unix_print)
+		$(meson_feature gnome thumbnail_cache)
+		$(meson_feature gstreamer multimedia)
+		$(meson_feature spell gspell)
+
+		-Dinternal_synctex=true
+
+		-Dsystemduserunitdir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}