dev-python/autobahn: Bump to 22.12.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 119 insertions, 0 deletions

diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
index 3fe91a90fc97..7f66cd9e69fb 100644
--- a/dev-python/autobahn/Manifest
+++ b/dev-python/autobahn/Manifest
@@ -1 +1,2 @@
+DIST autobahn-22.12.1.tar.gz 479515 BLAKE2B 37003c458b773b122716fd17e5245c3754e49e5c66601266870ce83fe4b7622553605d007902bd505897428231ce8347bf24548142dcb38631dc08f092be7eaf SHA512 10b3eec220a78b21aa393c9a721a9efb06b2623910ebb19dcf58c3966912cb9c5bbe5fc04d9f1072711a209a6a0168d7ba3a6147c1fc9a7db46bd528cc380dd0
 DIST autobahn-22.7.1.tar.gz 476789 BLAKE2B 4860a6ec1a2631986dd5d8e94069134e75650eedb67dce18dd4c1e8ad45bd76ca183b4dcbca6ef4474c25f6feb4a1407c9fed4c74f0751e9c0c7fbca2b013406 SHA512 ea2c4d61d3f0f8ef35a31b599bc432781536dccaa316cda474a61003b10df0ef6346615d16228848cc5acb24a4e5f4c50be1fe759daf35b629f636da55688137
diff --git a/dev-python/autobahn/autobahn-22.12.1.ebuild b/dev-python/autobahn/autobahn-22.12.1.ebuild
new file mode 100644
index 000000000000..a8fcd07d0687
--- /dev/null
+++ b/dev-python/autobahn/autobahn-22.12.1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1 optfeature
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python/
+	https://pypi.org/project/autobahn/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test xbr"
+RESTRICT="!test? ( test )"
+
+# The order of deps is based on their appearance in setup.py
+# All extra deps should be included in test and in optfeature
+RDEPEND="
+	>=dev-python/zope-interface-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-21.2.1[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		>=dev-python/wsaccel-0.6.3[${PYTHON_USEDEP}]
+		>=dev-python/snappy-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/ujson-4.0.2[${PYTHON_USEDEP}]
+		>=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
+		>=dev-python/py-ubjson-0.16.1[${PYTHON_USEDEP}]
+		>=dev-python/flatbuffers-22.12.06[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-20.0.1[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.4[${PYTHON_USEDEP}]
+		>=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
+		>=dev-python/argon2-cffi-20.1.0[${PYTHON_USEDEP}]
+		>=dev-python/passlib-1.7.4[${PYTHON_USEDEP}]
+
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	if use xbr ; then
+		eerror "***************"
+		eerror "Required xbr dependencies are incomplete in Gentoo."
+		eerror "So this functionality will not yet work"
+		eerror "Please file a bug if this feature is needed"
+		eerror "***************"
+	else
+		# remove xbr components
+		export AUTOBAHN_STRIP_XBR="True"
+	fi
+
+	# avoid useless rust dependency
+	sed -i -e '/cryptography/s:>=3.4.6::' setup.py || die
+
+	# remove twisted plugin cache regen in setup.py
+	# to fix tinderbox sandbox issue
+	sed -e '/import/s:reactor:__importmustfail__:' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	rm -rf autobahn || die
+
+	einfo "Testing all, cryptosign using twisted"
+	local -x USE_TWISTED=true
+	"${EPYTHON}" -m twisted.trial autobahn || die "Tests failed with ${EPYTHON}"
+	unset USE_TWISTED
+
+	einfo "RE-testing cryptosign and component_aio using asyncio"
+	local -x USE_ASYNCIO=true
+	epytest --pyargs autobahn.wamp.test.test_wamp_{cryptosign,component_aio}
+	unset USE_ASYNCIO
+
+	rm -f twisted/plugins/dropin.cache || die
+}
+
+pkg_postinst() {
+	optfeature "C-based WebSocket acceleration" "dev-python/wsaccel"
+	optfeature "non-standard WebSocket compression support" "dev-python/snappy"
+	optfeature "accelerated WAMP serialization support" \
+		"dev-python/msgpack dev-python/ujson dev-python/cbor2 dev-python/flatbuffers dev-python/py-ubjson"
+	optfeature "TLS transport encryption" \
+		"dev-python/pyopenssl dev-python/pynacl dev-python/pytrie dev-python/qrcode dev-python/service_identity"
+	optfeature "WAMP-SCRAM authentication" \
+		"dev-python/cffi dev-python/argon2-cffi dev-python/passlib"
+	optfeature "native SIMD acceleration" "dev-python/cffi"
+
+	python_foreach_impl twisted-regen-cache
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache
+}