dev-python/nbconvert: add 7.12.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index bd46da416051..9b6d637661f8 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1 +1,2 @@
 DIST nbconvert-7.11.0.tar.gz 851158 BLAKE2B 0506acda6a645ffba6771f600c63f0c37705481021b716a2b5ec61b49f2b9da490beac7a1fec67718d091d7bfcf82d7f07b68e207573ca5c08271fc502214eb1 SHA512 097e740413520b943afea11e2b797fbb163e1c34b79932597ec1c5a2c64bbb9342e4b3e1f0ab7e4d6dbdaa736d747650d8e0e50da0e4db5398151da8c3b57c59
+DIST nbconvert-7.12.0.tar.gz 851572 BLAKE2B e6f91a29790fc24901bfb527fc4335000af11354090c969d393eb1c95ad9f36c1e65e941a061b20ed884fd4e70316c6cdf1eb7ca115147ecb8a4726f62a98b83 SHA512 ba450938e7a907a6b5679e619b79ea6555f81b6f4ca387c3fab94377ce060d5b99424804052855451ec3f6f8a160355d58c6b875bdd3951a16c5dacae19a2c24
diff --git a/dev-python/nbconvert/nbconvert-7.12.0.ebuild b/dev-python/nbconvert/nbconvert-7.12.0.ebuild
new file mode 100644
index 000000000000..e6d12ff02703
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-7.12.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="
+	https://nbconvert.readthedocs.io/
+	https://github.com/jupyter/nbconvert/
+	https://pypi.org/project/nbconvert/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.7[${PYTHON_USEDEP}]
+	dev-python/jupyterlab-pygments[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.0[${PYTHON_USEDEP}]
+	<dev-python/mistune-4[${PYTHON_USEDEP}]
+	>=dev-python/nbclient-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.7[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.1[${PYTHON_USEDEP}]
+	dev-python/tinycss2[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-7[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	mkdir -p share/templates/classic/static || die
+	# tries to refetch stuff even if it's already present
+	sed -e 's:css = .*:raise PermissionError("You shall not fetch!"):' \
+		-i hatch_build.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_nbconvertapp.py::TestNbConvertApp::test_convert_full_qualified_name
+		tests/test_nbconvertapp.py::TestNbConvertApp::test_post_processor
+		# crazy qtweb* stuff, perhaps permissions
+		tests/exporters/test_qtpdf.py::TestQtPDFExporter::test_export
+		tests/exporters/test_qtpng.py::TestQtPNGExporter::test_export
+	)
+
+	# virtx implies nonfatal, make it explicit to avoid confusion
+	nonfatal epytest || die
+}
+
+pkg_postinst() {
+	if ! has_version virtual/pandoc; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc or app-text/pandoc-bin."
+	fi
+}