dev-python/pooch: Bump to 1.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/pooch/pooch-1.7.0.ebuild b/dev-python/pooch/pooch-1.7.0.ebuild
new file mode 100644
index 000000000000..2cc8a7f0a32f
--- /dev/null
+++ b/dev-python/pooch/pooch-1.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Manage your Python library's sample data files"
+HOMEPAGE="
+	https://github.com/fatiando/pooch/
+	https://pypi.org/project/pooch/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.5.0[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/paramiko[${PYTHON_USEDEP}]
+		dev-python/pytest-localftpserver[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Needs network
+	pooch/tests/test_core.py::test_check_availability_invalid_downloader
+	pooch/tests/test_core.py::test_load_registry_from_doi
+	pooch/tests/test_core.py::test_load_registry_from_doi_zenodo_with_slash
+	pooch/tests/test_downloaders.py::test_invalid_doi_repository
+	pooch/tests/test_downloaders.py::test_doi_url_not_found
+	pooch/tests/test_downloaders.py::test_figshare_url_file_not_found
+	pooch/tests/test_downloaders.py::test_doi_downloader
+)
+
+### docs no included in pypi tarball
+# distutils_enable_sphinx doc \
+#	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -k "not network"
+}