dev-python/tempest: add 36.0.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index a74318f86623..2cea7251f86b 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-35.0.0.tar.gz 1144022 BLAKE2B dd333ac1271ef51171ff7d06931138a6de5872a86e2ed49c4d94b37431f6f94092069eef6700e453ab6e5fc04f004f5bd040af64ea98531bf56eba5edc9394b3 SHA512 c8986e13c821c8861f0b9c1b37c71a1017cd6de480a5efdcc646b51d1c7032a236f98735d0f77240fc9ec9eb711638a12f7a4a8d67e99c76bc1f6b561c39c61d
+DIST tempest-36.0.0.tar.gz 1137446 BLAKE2B f645b35b42252dc2bb4b7e1a3f609ee31e76d60e952c2ebb2a404b5f2e40b449aed0815631e922dffc71bd1598a5554277b851f54b99a37a1af328de171ec3ac SHA512 1d931052aa3fd9c76dc6ea23f861d43842877158307877235f5fc64d8a2a0a65dedefebec7ef5a7153aad7ccc3fc9954a882696adbaa6800af9ea2eb652790dc
diff --git a/dev-python/tempest/tempest-36.0.0.ebuild b/dev-python/tempest/tempest-36.0.0.ebuild
new file mode 100644
index 000000000000..93fcb0ff084e
--- /dev/null
+++ b/dev-python/tempest/tempest-36.0.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	eunittest -b -s tempest/tests -t .
+}