dev-python/toml: Bump to 0.10.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/toml/toml-0.10.2.ebuild b/dev-python/toml/toml-0.10.2.ebuild
new file mode 100644
index 000000000000..2e0e4cab9bb6
--- /dev/null
+++ b/dev-python/toml/toml-0.10.2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+
+inherit distutils-r1
+
+TOML_TEST_VER="280497fa5f12e43d7233aed0d74e07ca61ef176b"
+
+DESCRIPTION="Python library for handling TOML files"
+HOMEPAGE="https://github.com/uiri/toml"
+SRC_URI="https://github.com/uiri/${PN}/archive/${PV}.tar.gz -> ${P}-1.tar.gz
+	test? ( https://github.com/BurntSushi/toml-test/archive/${TOML_TEST_VER}.tar.gz -> toml-test-${TOML_TEST_VER}.tar.gz )"
+IUSE="test"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/numpy[${PYTHON_USEDEP}]
+		' 'python*')
+	)"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	if use test; then
+		mv "${WORKDIR}/toml-test-${TOML_TEST_VER#v}" "${S}/toml-test" || die
+	fi
+
+	distutils-r1_python_prepare_all
+}