Merge updates from master

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/clang-python/clang-python-13.0.0.9999.ebuild b/dev-python/clang-python/clang-python-13.0.0.9999.ebuild
new file mode 100644
index 000000000000..0e3b3ea06300
--- /dev/null
+++ b/dev-python/clang-python/clang-python-13.0.0.9999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/lit/lit-13.0.0.9999.ebuild b/dev-python/lit/lit-13.0.0.9999.ebuild
new file mode 100644
index 000000000000..cd8a5985d342
--- /dev/null
+++ b/dev-python/lit/lit-13.0.0.9999.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm )"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}