media-libs/lilv: bump to 0.24.20 + updated homepage

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 76 insertions, 1 deletions

diff --git a/media-libs/lilv/Manifest b/media-libs/lilv/Manifest
index e5c9545da707..1a229de06277 100644
--- a/media-libs/lilv/Manifest
+++ b/media-libs/lilv/Manifest
@@ -1 +1,2 @@
 DIST lilv-0.24.18.tar.xz 118216 BLAKE2B c1d191a8513776b4e783f05076b8a8d5a20866e734527ff84e04d970d190b26d2c922aa6f7ba346632caea47daa265c1008d9295c3f0e41f85227103337ccd1f SHA512 eece846338403ba3e7c366024511d33bd5e399d3b1e6871d04ec3907540a9e3541ab7b0445bf17cf61c5779c5263f1ef23eadefb6411a2e4be8d79464a5b873e
+DIST lilv-0.24.20.tar.xz 118460 BLAKE2B 50b2044a7fb62cfcbea6dc68cd0d26503780f30a5a04e2ceafca9e02b2369965d7d27b8d08bbfa136930a3b18a3e0eb6cf4c326d3c2d46218badb4a8ec6e1e01 SHA512 68963b66fd6e577280867fcd5a601fd2cf539a10fcf0b667c22165cc7e42206fd6a20d56dbe97b587fb68f798d4db3b2351b87b1243c665c3a2b1bb82cbbf9a3
diff --git a/media-libs/lilv/lilv-0.24.18-r1.ebuild b/media-libs/lilv/lilv-0.24.18-r1.ebuild
index a4ebe7246ec7..9796de60ac02 100644
--- a/media-libs/lilv/lilv-0.24.18-r1.ebuild
+++ b/media-libs/lilv/lilv-0.24.18-r1.ebuild
@@ -9,7 +9,7 @@ PYTHON_REQ_USE='threads(+)'
 inherit meson-multilib python-single-r1
 
 DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
-HOMEPAGE="http://drobilla.net/software/lilv/"
+HOMEPAGE="https://drobilla.net/software/lilv.html"
 SRC_URI="http://download.drobilla.net/${P}.tar.xz"
 
 LICENSE="ISC"
diff --git a/media-libs/lilv/lilv-0.24.20.ebuild b/media-libs/lilv/lilv-0.24.20.ebuild
new file mode 100644
index 000000000000..9c461756fb0b
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.20.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit meson-multilib python-single-r1
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="https://drobilla.net/software/lilv.html"
+SRC_URI="http://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc python test tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx_lv2_theme
+	)
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/serd[${MULTILIB_USEDEP}]
+	dev-libs/sord[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	media-libs/lv2[${MULTILIB_USEDEP}]
+	media-libs/sratom[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s%install_dir: docdir / 'lilv-0',%install_dir: docdir / '${PF}',%g" doc/c/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature python bindings_py)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+	python_optimize
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+
+	newenvd - 60lv2 <<-EOF
+		LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
+	EOF
+}