media-libs/smpeg2: EAPI8 bump, ebuild improvements

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/21779
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 51 insertions, 2 deletions

diff --git a/media-libs/smpeg2/files/smpeg2-2.0.0-gcc6.patch b/media-libs/smpeg2/files/smpeg2-2.0.0-gcc6.patch
index 4094c61ba432..943b7ed552d9 100644
--- a/media-libs/smpeg2/files/smpeg2-2.0.0-gcc6.patch
+++ b/media-libs/smpeg2/files/smpeg2-2.0.0-gcc6.patch
@@ -2,8 +2,6 @@ gcc-6 is more strict WRT narrowing:
 error: narrowing conversion of ‘-1’ from ‘int’ to ‘unsigned int’ inside { } [-Wnarrowing]
 
 https://bugs.gentoo.org/594912
-diff --git a/audio/hufftable.cpp b/audio/hufftable.cpp
-index 6bc8e86..5414ae3 100644
 --- a/audio/hufftable.cpp
 +++ b/audio/hufftable.cpp
 @@ -552,3 +552,3 @@ const HUFFMANCODETABLE MPEGaudio::ht[HTN]=
diff --git a/media-libs/smpeg2/smpeg2-2.0.0-r4.ebuild b/media-libs/smpeg2/smpeg2-2.0.0-r4.ebuild
new file mode 100644
index 000000000000..b8ee861d4778
--- /dev/null
+++ b/media-libs/smpeg2/smpeg2-2.0.0-r4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+MY_P="smpeg-${PV}"
+
+DESCRIPTION="SDL MPEG Player Library"
+HOMEPAGE="https://icculus.org/smpeg/"
+SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug cpu_flags_x86_mmx static-libs"
+
+DEPEND="media-libs/libsdl2[${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc6.patch
+	"${FILESDIR}"/${P}-smpeg2-config.patch
+)
+
+src_prepare() {
+	default
+
+	# avoid file collision with media-libs/smpeg
+	sed -i -e '/plaympeg/d' Makefile.am || die
+
+	AT_M4DIR="${ESYSROOT}/usr/share/aclocal acinclude" eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-rpath
+		--disable-sdltest
+		--enable-debug # disabling this only passes extra optimizations
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable debug assertions)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}