media-libs/glycin-loaders: Bump to 1.1.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/media-libs/glycin-loaders/Manifest b/media-libs/glycin-loaders/Manifest
index 91b32d988f24..128dae3c9ce4 100644
--- a/media-libs/glycin-loaders/Manifest
+++ b/media-libs/glycin-loaders/Manifest
@@ -1 +1,2 @@
 DIST glycin-1.1.0.tar.xz 28570152 BLAKE2B 762c8208c5cc8bf6be93a8daa70cd22b1cbd93c60075ccf38225a10c303b2c503bdc1ec2e6efeb85f36f3787b45a6061926e314f44841a583e0e3cb3debc3d48 SHA512 6e4b84dceb8957f0ab6e840dbc60f6c9bb8179fde841075c614a9742282ea578a51a966eb8e7a2482daf631932e8ce5af2f1f41523f376f4d1a0a2069af94631
+DIST glycin-1.1.1.tar.xz 28914480 BLAKE2B ef39c3b15e9addd36c6bc7010bbdaf1d5efe7aeaf1a5562217c87310b16efae75b568ae0291f91815238bd4b01747cbc5d3eef26f945f0a21f008904cc382392 SHA512 ce3961b4cbe71739cdf24b985b5a609284e2cdb3869671606cbd0f31c5c99f80da7608f2e29df5a0cc7d7ef0f7bd5926eb3fff993e80cbd8ec03bf321b92b0f0
diff --git a/media-libs/glycin-loaders/glycin-loaders-1.1.1.ebuild b/media-libs/glycin-loaders/glycin-loaders-1.1.1.ebuild
new file mode 100644
index 000000000000..0775282f7108
--- /dev/null
+++ b/media-libs/glycin-loaders/glycin-loaders-1.1.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo meson
+
+MY_P=glycin-${PV/_/.}
+DESCRIPTION="Loaders for glycin clients (glycin crate or libglycin)"
+HOMEPAGE="https://gitlab.gnome.org/sophie-h/glycin/"
+SRC_URI="
+	https://download.gnome.org/sources/glycin/$(ver_cut 1-2)/${MY_P}.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD GPL-3+ ISC MIT
+	Unicode-DFS-2016
+	|| ( LGPL-2.1+ MPL-2.0 )
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="heif jpegxl svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.60:2
+	>=sys-libs/libseccomp-2.5.0
+	heif? ( >=media-libs/libheif-1.17.0:= )
+	jpegxl? ( >=media-libs/libjxl-0.10.0:= )
+	svg? (
+		>=gnome-base/librsvg-2.52.0:2
+		>=x11-libs/cairo-1.17.0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=gui-libs/gtk-4.12.0:4
+		>=media-libs/lcms-2.14:2
+	)
+"
+BDEPEND="
+	test? (
+		sys-apps/bubblewrap
+		sys-apps/dbus
+	)
+"
+
+ECARGO_VENDOR=${S}/vendor
+
+QA_FLAGS_IGNORED="usr/libexec/glycin-loaders/.*"
+
+src_prepare() {
+	default
+
+	# https://gitlab.gnome.org/sophie-h/glycin/-/issues/81
+	sed -i -e '\|/fonts|d' tests/tests.rs || die
+}
+
+src_configure() {
+	local formats=(
+		$(usev heif glycin-heif)
+		$(usev jpegxl glycin-jxl)
+		$(usev svg glycin-svg)
+		glycin-image-rs
+	)
+	local formats_s=${formats[*]}
+	local emesonargs=(
+		-Dprofile=$(usex debug dev release)
+		-Dglycin-loaders=true
+		-Dloaders="${formats_s// /,}"
+		-Dtests=$(usex test true false)
+		-Dlibglycin=false
+	)
+
+	meson_src_configure
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
+
+src_test() {
+	# tests write to /proc/*/uid_map
+	# apparently, "addpredict /" in Portage breaks it
+	local -x SANDBOX_ON=0
+	meson_src_test
+}