media-plugins/grilo-plugins: bump to 0.3.9

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/media-plugins/grilo-plugins/Manifest b/media-plugins/grilo-plugins/Manifest
index 92b4601b6866..eea3ce5dc69c 100644
--- a/media-plugins/grilo-plugins/Manifest
+++ b/media-plugins/grilo-plugins/Manifest
@@ -1 +1,2 @@
 DIST grilo-plugins-0.3.8.tar.xz 1408952 BLAKE2B 3375275189a25289406b5d9fd6dd42b6c0ad92779b081ce2f480b464929302af7b52fc758f2f6277c94fad38a2b0bbfc8fe9fd668ff98fc0ac7fbeda69a5ac42 SHA512 c5a0a80fd7c871ce69a06bdcab2b3d8986708e4e6b9c9020d7e938d4450655f962db7f84da0b40ed38ba197f65fc2a561e06a92cdca593620d66c2b153eb4879
+DIST grilo-plugins-0.3.9.tar.xz 1418148 BLAKE2B 438aac490f2e099c40f5df15d8b3958dc29c4344e4846a3ff452561f60bf041fe2975b6c67b634f5f54721fd69e53f86c5008eadb3a402cbc8b479e805ab8221 SHA512 4700b08cab53afe0899edf7859a2e18608f6ed2016a9139694e8f1eb628c5b7318b04fe1633406fd1685a8dd54d1632b886352eac3192d52a1c1a1ac55896479
diff --git a/media-plugins/grilo-plugins/grilo-plugins-0.3.9.ebuild b/media-plugins/grilo-plugins/grilo-plugins-0.3.9.ebuild
new file mode 100644
index 000000000000..b5e655269161
--- /dev/null
+++ b/media-plugins/grilo-plugins/grilo-plugins-0.3.9.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit gnome.org meson xdg
+
+DESCRIPTION="A collection of plugins for the Grilo framework"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="daap chromaprint flickr freebox gnome-online-accounts lua test thetvdb tracker upnp-av +youtube"
+
+# GOA is only optionally used by flickr and lua-factory plugins (checked at v0.3.8)
+# json-glib used by tmdb and lua; tmdb currently non-optional
+# TODO: validate upnp-av dleyna deps
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=media-libs/grilo-0.3.8:${SLOT}=[network,playlist]
+	freebox? (
+		net-dns/avahi )
+	>=dev-libs/gom-0.3.2-r1
+	chromaprint? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-chromaprint:1.0 )
+	dev-libs/json-glib
+	daap? (
+		>=net-libs/libdmapsharing-2.9.12:3.0 )
+	media-libs/libmediaart:2.0
+	net-libs/libsoup:2.4
+	dev-libs/libxml2:2
+	flickr? (
+		net-libs/liboauth )
+	dev-db/sqlite:3
+	>=dev-libs/totem-pl-parser-3.4.1
+	tracker? (
+		>=app-misc/tracker-0.10.5:= )
+	upnp-av? (
+		net-libs/dleyna-connector-dbus
+		net-misc/dleyna-server )
+	lua? (
+		>=dev-lang/lua-5.3
+		app-arch/libarchive
+		dev-libs/libxml2:2 )
+	thetvdb? (
+		app-arch/libarchive )
+	youtube? (
+		>=dev-libs/libgdata-0.9.1:= )
+
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.5
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	upnp-av? ( >=dev-util/gdbus-codegen-2.44 )
+	virtual/pkgconfig
+	lua? ( dev-util/gperf )
+"
+
+PATCHES=(
+	"${FILESDIR}"/0.3.8-meson-goa.patch # Support controlling g-o-a dep via 'goa' meson_options
+)
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-plugins-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" help/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable-bookmarks=yes
+		-Denable-chromaprint=$(usex chromaprint yes no)
+		-Denable-dleyna=$(usex upnp-av yes no)
+		-Denable-dmap=$(usex daap yes no)
+		-Denable-filesystem=yes
+		-Denable-flickr=$(usex flickr yes no)
+		-Denable-freebox=$(usex freebox yes no)
+		-Denable-gravatar=yes
+		-Denable-jamendo=yes
+		-Denable-local-metadata=yes
+		-Denable-lua-factory=$(usex lua yes no)
+		-Denable-magnatune=yes
+		-Denable-metadata-store=yes
+		-Denable-opensubtitles=yes
+		-Denable-optical-media=yes
+		-Denable-podcasts=yes
+		-Denable-raitv=yes
+		-Denable-shoutcast=yes
+		-Denable-thetvdb=$(usex thetvdb yes no)
+		-Denable-tmdb=yes
+		-Denable-tracker=$(usex tracker yes no)
+		-Denable-vimeo=yes
+		-Denable-youtube=$(usex youtube yes no)
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+	)
+	meson_src_configure
+}