media-sound/mpd: version bump to 0.19.12

Package-Manager: portage-2.2.27

2 files changed, 253 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 1071f76dfed7..f760c4242594 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,3 +1,4 @@
 DIST mpd-0.19.10.tar.xz 701668 SHA256 c386eb3d22f98dc993b5ae3c272f969aa7763713483c6800040ebf1791b15851 SHA512 037e1ccd69456bd7d388cbcba26de83144816684fb266995b173df960051e84203d3fc7255d7766eee5dbe0629dbb7745b9821664486158d33da4f29189edef8 WHIRLPOOL 02c2ec2c898fbeb9bf39ae9a2b57d85881825489a033f56b6140602f7cd6176f39d4aa09f0dfd2391214bd70d3ffab0e7a7eefcba8085e5ea7d15168028efa53
 DIST mpd-0.19.11.tar.xz 703064 SHA256 7a5c66aa5af97a5b7af3dc49e3d2594071dafd62a14e2e9f7c9a5a86342836c6 SHA512 3ad505a75651facd141efbb43ebb86a9f1b66a0bc044d39c9131068fc20d05037ad449935fd6fc20917dfd690cdc256c1d1deb7427039d2345b13bea2b2eb66e WHIRLPOOL da4a05fce7276e8f98acfe2a0eceb71e747049d9c64b7eed226b5e8e3b2c5fd197098b20509e5cb2ad2f280a4f3872439a893ad58677be5b79b251d57b04c90d
+DIST mpd-0.19.12.tar.xz 703340 SHA256 7b6fe6c7ce72f5f80a276d680072b524ecb395e546e252b8f3a0756377e1e875 SHA512 a608c99096d0ec9158cba5615be344a47d76c5be830ba34445e330f141aaa828784772d772df20d71d4c65e78ea5dfe9fb59ea4f4f823fa112a00517963a6e7e WHIRLPOOL ab1c0ba6a92f5582c774b36f10d2433ccd4b796cb38d35ff0accdf0d29b95268f13f462446b72df52f2b8fb4a7b5e297fb37d1303b38412c4e73f0769dbbf7bd
 DIST mpd-0.19.9.tar.xz 701480 SHA256 47851423053cd38cfad65be5985b41b7cd5bdbe8d0d13378e11748a28b19f26f SHA512 7d74254e009008ed142ce0b69e75fe6f255ec2c814b246f570225af715ec5c3a5c75276f4720bc1ad351d48be5b20f9797843c03aae9380a6062796539507bf4 WHIRLPOOL 04ee826f55512c5f4b28f0bfbf78e23710070970be2f7da07b421483da1d9dad20b0b3513a2529f88d83c92f8202cb57bad09fee894eb18387cbc156312e3a06
diff --git a/media-sound/mpd/mpd-0.19.12.ebuild b/media-sound/mpd/mpd-0.19.12.ebuild
new file mode 100644
index 000000000000..777cd2df38cb
--- /dev/null
+++ b/media-sound/mpd/mpd-0.19.12.ebuild
@@ -0,0 +1,252 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils flag-o-matic linux-info multilib readme.gentoo systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
+	+fifo +ffmpeg flac fluidsynth +glib gme +icu +id3tag +inotify +ipv6 jack
+	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
+	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
+	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
+	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	ao? ( glib )
+	gme? ( glib )
+	jack? ( glib )
+	network? ( || ( ${ENCODER_PLUGINS} )
+		glib )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	sid? ( glib )
+	soundcloud? ( glib )
+	sqlite? ( glib )
+	opus? ( ogg )
+	upnp? ( expat )
+	vorbis? ( glib )
+	wavpack? ( glib )"
+
+CDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	adplug? ( media-libs/adplug )
+	alsa? ( media-sound/alsa-utils
+		media-libs/alsa-lib )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio-paranoia )
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	glib? ( dev-libs/glib:2 )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( || ( <net-fs/samba-4.0.25[smbclient] >=net-fs/samba-4.0.25 ) )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2 )
+	libsoxr? ( media-libs/soxr )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${CDEPEND}
+	dev-libs/boost
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-mpd )
+"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	DOC_CONTENTS="If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.18.conf.patch
+}
+
+src_configure() {
+	local mpdconf="--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
+		--disable-solaris-output --enable-tcp --enable-un --disable-werror
+		--docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use samba || use upnp; then
+		mpdconf+=" --enable-neighbor-plugins"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable eventfd)		\
+		$(use_enable signalfd)		\
+		$(use_enable libmpdclient)	\
+		$(use_enable expat)			\
+		$(use_enable upnp)			\
+		$(use_enable adplug)		\
+		$(use_enable alsa)			\
+		$(use_enable ao)			\
+		$(use_enable audiofile)		\
+		$(use_enable zlib)			\
+		$(use_enable bzip2)			\
+		$(use_enable cdio cdio-paranoia) \
+		$(use_enable curl)			\
+		$(use_enable samba smbclient) \
+		$(use_enable nfs)			\
+		$(use_enable debug)			\
+		$(use_enable ffmpeg)		\
+		$(use_enable fifo)			\
+		$(use_enable flac)			\
+		$(use_enable fluidsynth)	\
+		$(use_enable gme)			\
+		$(use_enable id3tag id3)	\
+		$(use_enable inotify)		\
+		$(use_enable ipv6)			\
+		$(use_enable cdio iso9660)	\
+		$(use_enable jack)			\
+		$(use_enable soundcloud)	\
+		$(use_enable tcpd libwrap)	\
+		$(use_enable libsamplerate lsr) \
+		$(use_enable libsoxr soxr)	\
+		$(use_enable mad)			\
+		$(use_enable mikmod)		\
+		$(use_enable mms)			\
+		$(use_enable modplug)		\
+		$(use_enable musepack mpc)	\
+		$(use_enable mpg123)		\
+		$(use_enable openal)		\
+		$(use_enable opus)			\
+		$(use_enable oss)			\
+		$(use_enable pipe pipe-output) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable recorder recorder-output) \
+		$(use_enable sid sidplay)	\
+		$(use_enable sndfile sndfile) \
+		$(use_enable sqlite)		\
+		$(use_enable systemd systemd-daemon) \
+		$(use_enable vorbis)		\
+		$(use_enable wavpack)		\
+		$(use_enable wildmidi)		\
+		$(use_enable zip zzip)		\
+		$(use_enable icu)			\
+		$(use_enable glib)			\
+		$(use_enable faad aac)		\
+		$(use_with zeroconf zeroconf avahi) \
+		"$(systemd_with_unitdir)"	\
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}2.init ${PN}
+
+	systemd_newuserunit systemd/${PN}.service ${PN}.service
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}