media-sound/rhythmbox: bump to 3.4.3

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 127 insertions, 0 deletions

diff --git a/media-sound/rhythmbox/Manifest b/media-sound/rhythmbox/Manifest
index e099addb0ef3..43a8124a64c0 100644
--- a/media-sound/rhythmbox/Manifest
+++ b/media-sound/rhythmbox/Manifest
@@ -1 +1,2 @@
 DIST rhythmbox-3.4.2.tar.xz 6909436 BLAKE2B f5714485b253370a161f2255030d85bc8a697d795f97011c2acf6acbf8c9312f5180c0ec06ebe2d6e70730dc3fd4e97289b1f3a5e4dd4989a4e8135433430aab SHA512 275f7c6344c88c7331d433895d479517e7a4b854f6ae660abd79b3c324f5e7a06132fa44387443ec9ce50b20187e1abf1ec9683ec4bedbd4b17da6efece8399b
+DIST rhythmbox-3.4.3.tar.xz 6410600 BLAKE2B 0df8ac37ac0815468414c5b8118da6d07276e0c15f08812a46af7f377c29418416e1a24d7398aec10772887ae98922f6fb9fa9eaecc6ae15115cd7ca1c4b67a4 SHA512 a3585c026037674345909e2050a4ccb22a75084f830f351b926f7fbfc84d200c8246b8da4bd72804e595929ab06d3c7b53d362675dde193746f40b0f38b7c493
diff --git a/media-sound/rhythmbox/rhythmbox-3.4.3.ebuild b/media-sound/rhythmbox/rhythmbox-3.4.3.ebuild
new file mode 100644
index 000000000000..a9801c4d3bc9
--- /dev/null
+++ b/media-sound/rhythmbox/rhythmbox-3.4.3.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="xml"
+
+inherit eutils gnome2 python-single-r1 multilib virtualx
+
+DESCRIPTION="Music management and playback software for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Rhythmbox"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="cdr daap dbus gnome-keyring ipod libnotify lirc mtp nsplugin +python test +udev upnp-av"
+REQUIRED_USE="
+	ipod? ( udev )
+	mtp? ( udev )
+	dbus? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libxml2-2.7.8:2
+	>=x11-libs/gtk+-3.20.0:3[X,introspection]
+	>=x11-libs/gdk-pixbuf-2.18:2
+	>=dev-libs/gobject-introspection-0.10:=
+	>=dev-libs/libpeas-0.7.3[gtk]
+	>=dev-libs/totem-pl-parser-3.2
+	>=net-libs/libsoup-2.42:2.4
+	>=media-libs/gst-plugins-base-1.4:1.0[introspection]
+	>=media-libs/gstreamer-1.4:1.0[introspection]
+	>=sys-libs/tdb-1.2.6
+	dev-libs/json-glib
+
+	cdr? ( >=app-cdr/brasero-2.91.90 )
+	daap? (
+		>=net-libs/libdmapsharing-2.9.19:3.0
+		>=media-plugins/gst-plugins-soup-1.4:1.0 )
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	libnotify? ( >=x11-libs/libnotify-0.7.0 )
+	lirc? ( app-misc/lirc )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+	)
+	udev? (
+		virtual/libgudev:=
+		ipod? ( >=media-libs/libgpod-0.7.92[udev] )
+		mtp? ( >=media-libs/libmtp-0.3 ) )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-plugins/gst-plugins-soup:1.0
+	media-plugins/gst-plugins-libmms:1.0
+	|| (
+		media-plugins/gst-plugins-cdparanoia:1.0
+		media-plugins/gst-plugins-cdio:1.0 )
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/gst-plugins-taglib:1.0
+	x11-themes/adwaita-icon-theme
+	python? (
+		>=dev-libs/libpeas-0.7.3[python,${PYTHON_USEDEP}]
+		net-libs/libsoup:2.4[introspection]
+		x11-libs/gdk-pixbuf:2[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+
+		dbus? ( sys-apps/dbus )
+		gnome-keyring? ( >=app-crypt/libsecret-0.18[introspection] ) )
+	upnp-av? (
+		>=media-libs/grilo-0.3:0.3
+		>=media-plugins/grilo-plugins-0.3:0.3[upnp-av] )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35
+	dev-util/itstool
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+# eautoreconf needs yelp-tools
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# --enable-vala just installs the sample vala plugin, and the configure
+	# checks are broken, so don't enable it
+	gnome2_src_configure \
+		MOZILLA_PLUGINDIR=/usr/$(get_libdir)/nsbrowser/plugins \
+		VALAC=$(type -P true) \
+		--enable-mmkeys \
+		--disable-more-warnings \
+		--disable-static \
+		--disable-vala \
+		$(use_enable daap) \
+		$(use_enable libnotify) \
+		$(use_enable lirc) \
+		$(use_enable nsplugin browser-plugin) \
+		$(use_enable python) \
+		$(use_enable upnp-av grilo) \
+		$(use_with cdr brasero) \
+		$(use_with gnome-keyring libsecret) \
+		$(use_with ipod) \
+		$(use_with mtp) \
+		$(use_with udev gudev)
+}
+
+src_test() {
+	unset SESSION_MANAGER
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check CK_DEFAULT_TIMEOUT=60
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
+		MAINTAINERS MAINTAINERS.old NEWS README THANKS"
+
+	gnome2_src_install
+}