media-tv/gtk-v4l: update HOMEPAGE/SRC_URI, EAPI 5 -> 8

Closes: https://bugs.gentoo.org/699144
Signed-off-by: Marek Szuba <marecki@gentoo.org>

3 files changed, 38 insertions, 37 deletions

diff --git a/media-tv/gtk-v4l/gtk-v4l-0.4-r1.ebuild b/media-tv/gtk-v4l/gtk-v4l-0.4-r1.ebuild
new file mode 100644
index 000000000000..ac48862a1722
--- /dev/null
+++ b/media-tv/gtk-v4l/gtk-v4l-0.4-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="A GTK+ application for controlling V4L preferences of a web cam device"
+HOMEPAGE="https://github.com/jwrdegoede/gtk-v4l/"
+# No 0.4 release tag on GitHub so until 0.5 has been released, stick
+# with the previously mirrored tarball from FedoraHosted.
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=dev-libs/glib-2
+	dev-libs/libgudev:=
+	>=media-libs/libv4l-0.6
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.4-device-remove-source-on-finalize.patch
+)
+
+src_prepare() {
+	default
+	sed -i -e '/^Categories/s:Application:GTK:' ${PN}.desktop.in || die
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-tv/gtk-v4l/gtk-v4l-0.4.ebuild b/media-tv/gtk-v4l/gtk-v4l-0.4.ebuild
deleted file mode 100644
index cb4606812e7e..000000000000
--- a/media-tv/gtk-v4l/gtk-v4l-0.4.ebuild
+++ /dev/null
@@ -1,37 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit epatch
-
-DESCRIPTION="A control application for Video 4 Linux (based on C and GTK+)"
-HOMEPAGE="http://fedorahosted.org/gtk-v4l/"
-SRC_URI="http://fedorahosted.org/releases/${PN:0:1}/${PN:1:1}/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND=">=dev-libs/glib-2
-	dev-libs/libgudev:=
-	>=media-libs/libv4l-0.6
-	x11-libs/gtk+:3"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-DOCS="AUTHORS ChangeLog README"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-device-remove-source-on-finalize.patch
-	sed -i -e '/^Categories/s:Application:GTK:' ${PN}.desktop.in || die
-}
-
-src_configure() {
-	econf --disable-static
-}
-
-src_install() {
-	default
-	find "${ED}" -name '*.la' -delete || die
-}
diff --git a/media-tv/gtk-v4l/metadata.xml b/media-tv/gtk-v4l/metadata.xml
index 115e9d64a669..3778382e9dce 100644
--- a/media-tv/gtk-v4l/metadata.xml
+++ b/media-tv/gtk-v4l/metadata.xml
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<!-- maintainer-needed -->
+	<upstream>
+		<remote-id type="github">jwrdegoede/gtk-v4l</remote-id>
+	</upstream>
 </pkgmetadata>