net-im/gajim: Version bump

Closes: https://bugs.gentoo.org/845318
Signed-off-by: Hanno Böck <hanno@gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

2 files changed, 98 insertions, 0 deletions

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index b6c3b2c6eb49..90421df2906f 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -2,3 +2,4 @@ DIST gajim-1.3.3-2.tar.gz 9578053 BLAKE2B de41eb488480c1e9267a7e64c33dcc225ba683
 DIST gajim-1.3.3.tar.gz 9886175 BLAKE2B 27c4163a5762e8fa72524f91d846439b5bd54aff8ec0c4f8ffe4061295540d986b71fc333a2d65110e87821efc5a96ce0dc8a519236c5d71df9a722c65851296 SHA512 b1b6ed1eeb9ce01c26240a0a0c1ff3991ac305787e2ed49ecf7ed9cc75789da2d0ec1c3a1fda6dc67fe440fa7aa143af9be1a837acfc94255d7027f63f55ced2
 DIST gajim-1.4.0.tar.gz 8932710 BLAKE2B 66924bf2e0f39c74e0ce45bfb24c6bd41c547f170c149611dc08e45db1f665f1159be6586dde1a64f1037de029dc2d83c1146545c36645dd67b63509ce156043 SHA512 9fb2b967325d04d7cfa8cb97d0dcebdd5cfd8b8a0a4f8928e7d8c547d90567b7fb0d84d48cdd151b5e38ce72f65de2679c8cc1543ff3ed25d792e6de070042a0
 DIST gajim-1.4.1.tar.gz 7321296 BLAKE2B 2b170800a1ee6304831e1ec7c006e2133c577dd6b34da4e89ab35a6032677c7db61939834a5b3ad73026b7417703321dc43bb63aa2d0c03676cddb728c7294e6 SHA512 614b96d1e64e8601992d608de279abdd38fcfa637094eeffef6adab725446b8955d07725a3d7577d71be4b883943e3341f84540a86e9a61c32ec51ae8999cfcc
+DIST gajim-1.4.2.tar.gz 7315938 BLAKE2B 2315be3d8efa98bf45cc7479a38a83f6d297bc4af9550ce70ccbb9f4fce681cdec57658f2c5c12c4b3b1b97d7623b1da32b675be971e186623957a267010d85c SHA512 d3402b39c9253334523538b86c3e2d6f272f576824048b344a235a12982c53280c3638b0b299c536ed38bcb8648388ba5bea8056c722cc8a5dc5d98012f6d57c
diff --git a/net-im/gajim/gajim-1.4.2.ebuild b/net-im/gajim/gajim-1.4.2.ebuild
new file mode 100644
index 000000000000..60900668dd5d
--- /dev/null
+++ b/net-im/gajim/gajim-1.4.2.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="sqlite,xml"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jabber client written in PyGTK"
+HOMEPAGE="https://gajim.org/"
+SRC_URI="https://gajim.org/downloads/$(ver_cut 1-2)/${P/_p/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+crypt geolocation jingle omemo remote rst +spell upnp +webp"
+S="${WORKDIR}/${P%_p2}"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo(+)]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	x11-libs/gtksourceview:4"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/precis-i18n[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		>=dev-python/python-nbxmpp-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/python-nbxmpp-4.0.0[${PYTHON_USEDEP}]
+		x11-libs/libXScrnSaver
+		app-crypt/libsecret[crypt,introspection]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		>=dev-python/secretstorage-3.1.1[${PYTHON_USEDEP}]
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		net-libs/libsoup[introspection]
+		media-libs/gsound[introspection]
+		crypt? (
+			dev-python/pycryptodome[${PYTHON_USEDEP}]
+			>=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+		geolocation? ( app-misc/geoclue[introspection] )
+		jingle? (
+			net-libs/farstream:0.2[introspection]
+			media-libs/gstreamer:1.0[introspection]
+			media-libs/gst-plugins-base:1.0[introspection]
+			media-libs/gst-plugins-ugly:1.0
+			media-plugins/gst-plugins-gtk
+		)
+		omemo? (
+			dev-python/python-axolotl[${PYTHON_USEDEP}]
+			dev-python/qrcode[${PYTHON_USEDEP}]
+			dev-python/cryptography[${PYTHON_USEDEP}]
+		)
+		remote? (
+			>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+			sys-apps/dbus[X]
+		)
+		rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+		spell? (
+			app-text/gspell[introspection]
+			app-text/hunspell
+		)
+		upnp? ( net-libs/gupnp-igd[introspection] )
+		webp? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	')"
+
+src_install() {
+	distutils-r1_src_install
+
+	# avoid precompressed man pages
+	rm -r "${D}/usr/share/man"
+	doman data/*.1
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+# Tests are unfortunately regularly broken
+RESTRICT="test"