net-libs/libhubbub: bump to 0.3.6 and fix for json-c issue.

Also add myself as proxy maintainer.  Others are welcome to contribute,
my only interest here is in libwebsockets.

Closes: https://bugs.gentoo.org/694042
Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Jaco Kroon <jaco@uls.co.za>
Closes: https://github.com/gentoo/gentoo/pull/13566
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/net-libs/libhubbub/libhubbub-0.3.6.ebuild b/net-libs/libhubbub/libhubbub-0.3.6.ebuild
new file mode 100644
index 000000000000..7a2bdd8ebcbf
--- /dev/null
+++ b/net-libs/libhubbub/libhubbub-0.3.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="HTML5 compliant parsing library, written in C"
+HOMEPAGE="https://www.netsurf-browser.org/projects/hubbub/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~m68k-mint"
+IUSE="doc test"
+
+BDEPEND="
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig
+
+	test? ( dev-lang/perl )
+"
+RDEPEND="dev-libs/libparserutils:="
+DEPEND="${RDEPEND}
+	test? ( dev-libs/json-c )"
+RESTRICT="!test? ( test )"
+
+DOCS=( README docs/{Architecture,Macros,Todo,Treebuilder,Updated} )
+PATCHES=( "${FILESDIR}/libhubbub-0.3.6-json-c.patch" )
+
+src_prepare() {
+	default
+	sed -e '1i#pragma GCC diagnostic ignored "-Wimplicit-fallthrough"' \
+		-i test/tree2.c || die
+}
+
+_emake() {
+	source /usr/share/netsurf-buildsystem/gentoo-helpers.sh
+	netsurf_define_makeconf
+	append-cflags -Wno-error
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+}