net-voip/blink: initial import of version 1.4.1

Gentoo-Bug: 365131

4 files changed, 87 insertions, 0 deletions

diff --git a/net-voip/blink/Manifest b/net-voip/blink/Manifest
new file mode 100644
index 000000000000..17866a17d269
--- /dev/null
+++ b/net-voip/blink/Manifest
@@ -0,0 +1 @@
+DIST blink-1.4.1.tar.gz 1640252 SHA256 4e9fe9ccb62029085d551e82d7b1dd8e4d65ce15b35228e2a9a54c08ea1bec52 SHA512 9181eca2b9ee8b99a4c12ae8667b5988f86b1dda10afaf337b6b29dc2fa8733fc9737926014355c11a9913ebd5b406e2d241a4632bb19e4571ed7d318a15940b WHIRLPOOL 329589964e1ad575b1917661af874af1598b05110004ad07a86b1f7bb171eb797603c0c147359f1ad72c78e9af9f102c6a55e9053c1641b4d96b29017ad0f897
diff --git a/net-voip/blink/blink-1.4.1.ebuild b/net-voip/blink/blink-1.4.1.ebuild
new file mode 100644
index 000000000000..1ab78e46d697
--- /dev/null
+++ b/net-voip/blink/blink-1.4.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils gnome2-utils distutils-r1
+
+DESCRIPTION="A state of the art, easy to use SIP client"
+HOMEPAGE="http://iCanBlink.com"
+SRC_URI="http://download.ag-projects.com/BlinkQt/blink-${PV}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE=""
+
+KEYWORDS="~amd64 ~x86"
+
+CDEPEND="net-libs/libvncserver"
+RDEPEND="${CDEPEND}
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/PyQt4[webkit,${PYTHON_USEDEP}]
+	dev-python/python-application[${PYTHON_USEDEP}]
+	dev-python/python-cjson[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-eventlib[${PYTHON_USEDEP}]
+	dev-python/python-sipsimple[${PYTHON_USEDEP}]
+	dev-python/twisted-core[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+DEPEND="${CDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]"
+
+PATCHES=( "${FILESDIR}/${P}-data-path.patch" )
+
+src_install() {
+	distutils-r1_src_install
+
+	newicon -s 48 resources/icons/blink48.png blink.png
+	newicon -s 64 resources/icons/blink64.png blink.png
+	doicon -s 512 resources/icons/blink.png
+
+	make_desktop_entry ${PN} Blink
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/net-voip/blink/files/blink-1.4.1-data-path.patch b/net-voip/blink/files/blink-1.4.1-data-path.patch
new file mode 100644
index 000000000000..1add3ab55a23
--- /dev/null
+++ b/net-voip/blink/files/blink-1.4.1-data-path.patch
@@ -0,0 +1,19 @@
+From: Julian Ospald <hasufell@gentoo.org>
+Date: Tue Sep  8 10:10:18 UTC 2015
+Subject: Fix data path fallback
+
+Distutils installs into "/usr/share/blink", but
+blink was unable to find it on gentoo, probably due
+to python-exec magic.
+
+--- blink-1.4.1/blink/resources.py
++++ blink-1.4.1/blink/resources.py
+@@ -71,7 +71,7 @@
+             if os.path.exists(os.path.join(application_directory, 'resources', 'blink.ui')):
+                 cls._cached_directory = os.path.join(application_directory, 'resources').decode(sys.getfilesystemencoding())
+             else:
+-                cls._cached_directory = os.path.join(application_directory, 'share', 'blink').decode(sys.getfilesystemencoding())
++                cls._cached_directory = os.path.join(sys.prefix, 'share', 'blink').decode(sys.getfilesystemencoding())
+         return DirectoryContextManager(cls._cached_directory)
+ 
+     @classmethod
diff --git a/net-voip/blink/metadata.xml b/net-voip/blink/metadata.xml
new file mode 100644
index 000000000000..3a6254875166
--- /dev/null
+++ b/net-voip/blink/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>python</herd>
+	<maintainer>
+		<email>hasufell@gentoo.org</email>
+		<name>Julian Ospald</name>
+	</maintainer>
+</pkgmetadata>