sys-kernel/gentoo-kernel-bin: add 5.4.158-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 672851f2e54c..8b77cc7b7940 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -73,6 +73,7 @@ DIST gentoo-kernel-5.4.157-1.amd64.xpak 61363009 BLAKE2B 98893eddbd303aaec3f2d3e
 DIST gentoo-kernel-5.4.157-1.arm64.xpak 57637045 BLAKE2B 1c641c638ea6e6285361c6de947015e866802035fabbb3adaa645f1c5bb56432eb9f9131cfd8286b4d257a250f2c85df687f2df64469599e51a5fb6626af0d8e SHA512 756329d52db77da7586100b778217fbe1e29c671283fb87c3a55be6ded1695f3f561a179c2cf21c80324205e2ab35144e0f7225fd5d8c6fe957fb3f61025718d
 DIST gentoo-kernel-5.4.157-1.x86.xpak 53194026 BLAKE2B 33fe49f1e94a0648180149dff4a803d16f8bd135949d44e7c652276bc797bf2ef6dfcde0367261d54559468a13b18a114ca13ef72d13f434868baac7a07b2964 SHA512 51f391a51b09a8ba4368bb210fc0d84b25c88f5af61fa619390236ac6be409f8db791cb9949e1243f5e45a5056ffc4eda25ffadbe82da3a32929d49350d8dad9
 DIST gentoo-kernel-5.4.158-1.amd64.xpak 61365744 BLAKE2B 985463752628a98755f7765199cafc22a742661e2b2b4754b0f0ee4d3d1d96ee890eccf099f26be3e58a3f78fe770080c9dfb83f0fee00c4c79c23717fa021e4 SHA512 3a7a4890768af369d07566fac6e75ff482c3488a246c95911612ece436b0ffb9c26c87ba951dec49fece3d5bef90a238fa984a494dd3dfb7460ccb8f01293ef3
+DIST gentoo-kernel-5.4.158-1.arm64.xpak 57629591 BLAKE2B 75bfe916311d6b16bf2b8a8f7a641b359b1f94b24fd35cc728e424f1df4e66579dc614f52b1fddd2cb1c2929b40dec26993fba8933a054a4d412078eca7a8eac SHA512 6b7cf2d6796dcdb567fe2c84a968726145e492799c7f40a92e501a84df385ca7da213ffd72799bae483558e7528029a97fb68757a9685272690dc2c88d70abe0
 DIST gentoo-kernel-5.4.158-1.x86.xpak 53194465 BLAKE2B 4419edde2a05c5c375e085026a85b314800cbe571fd0e30f0a2123adb6db1aff60f1c0ed60611ffd756c22a8b42b69382c15c4a59d9046781bf57b9cd83e764e SHA512 c8695b6a312bde4a9f2807f79547d58f678865bf7c18435f1fc98ea285b9428de6e60885b12310d92d2f0f50a694ec583ea42a69956e5d5e1496efb33d7de3d6
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.13.tar.xz 119297284 BLAKE2B 9c4c12e2394dec064adff51f7ccdf389192eb27ba7906db5eda543afe3d04afca6b9ea0848a057571bf2534eeb98e1e3a67734deff82c0d3731be205ad995668 SHA512 a8edf97e9d38a49f1be2bde1e29ad96274bb2c6f7e8a2bebaa1161dd4df9cabcbaec4ff644c45bee94f86ae47725087d6deed0cd954209cec717621d137db85e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.158-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.158-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.158-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}