sys-kernel/gentoo-kernel-bin: add 5.14.20-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index fcdb0ccbd02b..8e8c336f9bcd 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -90,6 +90,7 @@ DIST gentoo-kernel-5.14.18-1.x86.xpak 59188901 BLAKE2B 130d30b9d22ea59a1dcc78080
 DIST gentoo-kernel-5.14.19-1.amd64.xpak 68129075 BLAKE2B c931708e9f8edf2707ed5d98247485a23a8691501546620507154cf023154a4c3eedaea384a91c6dfeda5458a9eaa0a904709d06cb0c65326c3bd0ae45db7f03 SHA512 2a41317d2215c1fcb7ed2a17316a9246ffb9fa1f09d7ec3e5b99ebeb175ef8648f388dbef4fbf75b251439e94179e8373d5deeec82d9550aa9326c661fe72207
 DIST gentoo-kernel-5.14.19-1.x86.xpak 59191582 BLAKE2B 3d43805e4b1bcb333e87668ca2b836087a2a51272da19cf65905d9251b7be0b1dd36464c2eba7f6b0ec068e3291a73ea8bb80ccbde3d27ed320f74d55521744a SHA512 a266d1ed04171f09102006177970a7f385cfc5409d2cbde157581e5bec6b64e4532f581c662d12472589e214714e2d7371f9adb7ef7c6d655645d57fe99edc18
 DIST gentoo-kernel-5.14.20-1.amd64.xpak 68144100 BLAKE2B fef36b61841ab6f5bea3f304c10315bfb3afb57910968e1562b5e4dd7c5cda9d1fe7529b3b140cf32ba9cb753753c6216bfb1ae4b1099477cd23a6e312a4c37c SHA512 0eb407bf5e84b132abf238c38c842745ebd3f07cd3fbdcdc35912b47389d6a4595eddaf874a2be7e0204dfe15705e299f8e1cf7a56106631e2331244be30a802
+DIST gentoo-kernel-5.14.20-1.arm64.xpak 63105775 BLAKE2B 6a5eabe8c298a767f8058887fcc610cd3c59d70a14eea5a6ec9af5192a16136d0fac7103c1db6563ee922a6229b8a9be7762e9f47a57a9a4dcce41d45615197a SHA512 d155f1ec48deb43edf569c6be6c44b411dc41148bb393047df726a23ae128093b3f4337e35e9641e48849507b59e8f90ec974508fd5ca80b27ea0eb5df7e2600
 DIST gentoo-kernel-5.14.20-1.x86.xpak 59196770 BLAKE2B 53d9544223b5a2dff33e46d63c3b02f3f05ab4b1702780d3648d6d6c770069750ab4fc96f07b55cda993bd332a977db562456f591ba2890aea786585d6793c92 SHA512 6d7cf027e366c45cacd014252f9b79ac78cdc18b450746546ebbf8506da5361262795f2921b00485a1659a5ec7bf6498e0b6d4c9c19649cb9a17498687fc73f2
 DIST gentoo-kernel-5.15.1-1.amd64.xpak 68887176 BLAKE2B b431ba6e360cb987f6f72ec643762ffa9e77997c9eec3713be51105e362ececcc338410630383070c72b8a41a06b1660e414d41349e3dea0c6a9f2ce80383200 SHA512 80785b528d89c71c6e9ac4af3806c117025e6d21ff6bb5433fcbb1132c83341a9ef3cd6aa7914088a0f2d353f485d681d0311fa46fbdd0faaedb856e0cd03bd7
 DIST gentoo-kernel-5.15.1-1.x86.xpak 59745113 BLAKE2B a21641e1d691abbfd6a70b0f1b40d75480c43ba2a9625ce62945eae5685f39da0ef92f164fa443cfd0096bb670b4e7a537f2b566218cd2deb9c41cfc7cf8afc5 SHA512 4bcb87087cc1afdf6a3d8e61546ad03c231d0d24048029b684a307e4b7bae431156f9d46f03c0e35a62e0524dc0f8e4d7146c5c8010d484814e42af3ad3f8e2b
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.20-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.20-r1.ebuild
new file mode 100644
index 000000000000..68f84f5bdd4c
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.20-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}