1 files changed, 42 insertions, 0 deletions
diff --git a/net-dns/openresolv/openresolv-3.11.0.ebuild b/net-dns/openresolv/openresolv-3.11.0.ebuild
new file mode 100644
index 000000000000..45ba61bc2c8d
--- /dev/null
+++ b/net-dns/openresolv/openresolv-3.11.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A framework for managing DNS information"
+HOMEPAGE="https://roy.marples.name/projects/openresolv"
+SRC_URI="https://roy.marples.name/downloads/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-resolvconf )"
+
+src_configure() {
+	local myeconfargs=(
+		--prefix="${EPREFIX}"
+		--rundir="${EPREFIX}"/var/run
+		--libexecdir="${EPREFIX}"/lib/resolvconf
+	)
+	econf "${myeconfargs[@]}"
+}
+
+pkg_config() {
+	if [[ ${ROOT} != / ]]; then
+		eerror "We cannot configure unless \$ROOT=/"
+		return 1
+	fi
+
+	if [[ -n "$(resolvconf -l)" ]]; then
+		einfo "${PN} already has DNS information"
+	else
+		ebegin "Copying /etc/resolv.conf to resolvconf -a dummy"
+		resolvconf -a dummy </etc/resolv.conf
+		eend $? || return $?
+		einfo "The dummy interface will disappear when you next reboot"
+	fi
+}
+
+DOCS=( LICENSE README.md )