1 files changed, 35 insertions, 0 deletions
diff --git a/sci-mathematics/cadical/cadical-1.5.3.ebuild b/sci-mathematics/cadical/cadical-1.5.3.ebuild
new file mode 100644
index 000000000000..dac39982db2e
--- /dev/null
+++ b/sci-mathematics/cadical/cadical-1.5.3.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Simplified Satisfiability Solver"
+HOMEPAGE="http://fmv.jku.at/cadical/"
+SRC_URI="https://github.com/arminbiere/${PN}/archive/rel-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-rel-${PV}
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-configure.patch
+	"${FILESDIR}"/${PN}-makefile.in-ar.patch
+)
+
+DOCS=( BUILD.md CONTRIBUTING NEWS.md README.md VERSION )
+
+src_configure() {
+	tc-export AR
+	CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} ${LDFLAGS}" ./configure || die
+}
+
+src_install() {
+	exeinto /usr/bin
+	doexe build/{cadical,mobical}
+	dolib.a build/libcadical.a
+	doheader src/cadical.hpp
+	einstalldocs
+}