blob: c2921bdfc7fe3e4631b83c7217a84c51380c5e0e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit cmake-utils multibuild qmake-utils
DESCRIPTION="Qt Cryptographic Architecture (QCA)"
HOMEPAGE="http://delta.affinix.com/qca/"
SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="2"
KEYWORDS="alpha amd64 ~arm ~arm64 hppa ~ia64 ppc ~ppc64 ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
IUSE="botan debug doc examples gcrypt gpg libressl logger nss pkcs11 +qt4 qt5 sasl softstore +ssl test"
REQUIRED_USE="|| ( qt4 qt5 )"
RDEPEND="
!app-crypt/qca-cyrus-sasl
!app-crypt/qca-gnupg
!app-crypt/qca-logger
!app-crypt/qca-ossl
!app-crypt/qca-pkcs11
botan? ( dev-libs/botan:0 )
gcrypt? ( dev-libs/libgcrypt:= )
gpg? ( app-crypt/gnupg )
nss? ( dev-libs/nss )
pkcs11? (
!libressl? ( dev-libs/openssl:0 )
libressl? ( dev-libs/libressl )
dev-libs/pkcs11-helper
)
qt4? ( dev-qt/qtcore:4 )
qt5? (
dev-qt/qtcore:5
dev-qt/qtconcurrent:5
dev-qt/qtnetwork:5
)
sasl? ( dev-libs/cyrus-sasl:2 )
ssl? (
!libressl? ( >=dev-libs/openssl-1.0.1:0= )
libressl? ( dev-libs/libressl:= )
)
"
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
test? (
qt4? ( dev-qt/qttest:4 )
qt5? ( dev-qt/qttest:5 )
)
"
DOCS=( README TODO )
PATCHES=(
"${FILESDIR}/${PN}-disable-pgp-test.patch"
)
qca_plugin_use() {
echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
}
pkg_setup() {
MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
}
src_configure() {
myconfigure() {
local mycmakeargs=(
-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_mkspecsdir)/features"
-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_plugindir)"
$(qca_plugin_use botan)
$(qca_plugin_use gcrypt)
$(qca_plugin_use gpg gnupg)
$(qca_plugin_use logger)
$(qca_plugin_use nss)
$(qca_plugin_use pkcs11)
$(qca_plugin_use sasl cyrus-sasl)
$(qca_plugin_use softstore)
$(qca_plugin_use ssl ossl)
$(cmake-utils_use_build test TESTS)
)
if [[ ${MULTIBUILD_VARIANT} == qt4 ]]; then
mycmakeargs+=(-DQT4_BUILD=ON)
fi
cmake-utils_src_configure
}
multibuild_foreach_variant myconfigure
}
src_compile() {
multibuild_foreach_variant cmake-utils_src_compile
}
src_test() {
mytest() {
local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
cmake-utils_src_test
}
multibuild_foreach_variant mytest
}
src_install() {
multibuild_foreach_variant cmake-utils_src_install
if use doc; then
pushd "${BUILD_DIR}" >/dev/null || die
doxygen Doxyfile.in || die
dodoc -r apidocs/html
popd >/dev/null || die
fi
if use examples; then
dodoc -r "${S}"/examples
fi
}
|
GitWeb