blob: d8cb4b874391d0946fcce0db48fa33e55a89ed7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit flag-o-matic toolchain-funcs user
DESCRIPTION="SKK dictionary server based on cdb"
HOMEPAGE="https://github.com/jj1bdx/dbskkd-cdb"
SRC_URI="https://github.com/jj1bdx/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
DEPEND="|| (
dev-db/tinycdb
dev-db/cdb
)"
RDEPEND="app-i18n/skk-jisyo[cdb]
sys-apps/xinetd"
PATCHES=( "${FILESDIR}"/${PN}-gentoo.patch )
DOCS="*.md"
pkg_setup() {
enewuser dbskkd -1 -1 -1
}
src_prepare() {
default
local cdblib=()
if has_version dev-db/cdb; then
append-cflags -I"${EPREFIX}"/usr/include/cdb
local a
for a in cdb.a alloc.a buffer.a byte.a unix.a; do
cdblib+=( "${EPREFIX}"/usr/$(get_libdir)/${a} )
done
else
cdblib+=( -lcdb )
fi
sed -i "/^CDBLIB/s|=.*$|= ${cdblib[*]}|" Makefile
}
src_compile() {
emake \
CC="$(tc-getCC)" \
COMPAT="-DJISYO_FILE=\\\"${EPREFIX}/usr/share/skk/SKK-JISYO.L.cdb\\\""
}
src_install() {
exeinto /usr/libexec
doexe ${PN}
einstalldocs
insinto /etc/xinetd.d
newins "${FILESDIR}"/${PN}.xinetd ${PN}
}
|
GitWeb
