blob: bd319146baa0168aeaf31952893541a336aa7fd9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..2} )
inherit autotools lua-single
DESCRIPTION="Worker Filemanager: Amiga Directory Opus 4 clone"
HOMEPAGE="http://www.boomerangsworld.de/cms/worker/"
SRC_URI="http://www.boomerangsworld.de/cms/worker/downloads/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm ~hppa ppc ~ppc64 x86"
IUSE="avfs debug dbus examples libnotify lua +magic xinerama xft"
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
RDEPEND="x11-libs/libX11
avfs? ( >=sys-fs/avfs-0.9.5 )
dbus? ( sys-apps/dbus )
lua? ( ${LUA_DEPS} )
magic? ( sys-apps/file )
xft? ( x11-libs/libXft )
xinerama? ( x11-libs/libXinerama )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( AUTHORS ChangeLog INSTALL NEWS README README_LARGEFILES THANKS )
src_prepare() {
default
# Don't use /usr/share/appdata
sed -i -e "s:/appdata:/metainfo:" contrib/Makefile.am || die
eautoreconf
}
src_configure() {
# there is no ./configure flag to disable libXinerama support
export ac_cv_lib_Xinerama_XineramaQueryScreens=$(usex xinerama)
econf \
--without-hal \
--enable-utf8 \
$(use_with avfs) \
$(use_with dbus) \
$(use_enable debug) \
$(use_enable libnotify inotify) \
$(use_enable lua) \
$(use_with magic libmagic) \
$(use_enable xft)
}
src_install() {
default
if use examples; then
docinto examples
dodoc examples/config-*
fi
}
|
GitWeb
