blob: 2df213efbbff0858b9f0be8435d7362795098edd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop eutils flag-o-matic xdg-utils
MY_P="${PN}libre-${PV#*_p}"
DESCRIPTION="DjVu viewers, encoders and utilities"
HOMEPAGE="http://djvu.sourceforge.net/"
SRC_URI="http://downloads.sourceforge.net/djvu/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
IUSE="debug doc jpeg tiff xml"
PATCHES=( "${FILESDIR}"/fix-CVE-2019-18804.patch )
RDEPEND="jpeg? ( virtual/jpeg:0 )
tiff? ( media-libs/tiff:0= )"
DEPEND="${RDEPEND}
|| ( gnome-base/librsvg media-gfx/inkscape )"
S=${WORKDIR}/${MY_P%%.3}
src_configure() {
use debug && append-cppflags "-DRUNTIME_DEBUG_ONLY"
# We install all desktop files by hand.
econf \
$(use_enable xml xmltools) \
$(use_with jpeg) \
$(use_with tiff) \
--disable-desktopfiles
}
DOCS=( NEWS README )
src_install() {
default
find "${ED}" -name '*.la' -delete || die
use doc && dodoc -r doc
# Install desktop files.
cd desktopfiles
for i in {22,32,48,64}; do
insinto /usr/share/icons/hicolor/${i}x${i}/mimetypes
newins prebuilt-hi${i}-djvu.png image-vnd.djvu.png
done
insinto /usr/share/mime/packages
doins djvulibre-mime.xml
}
pkg_postinst() {
xdg_icon_cache_update
xdg_mimeinfo_database_update
has_version app-text/djview || \
optfeature "For djviewer or browser plugin" app-text/djview
}
pkg_postrm() {
xdg_icon_cache_update
xdg_mimeinfo_database_update
}
|
GitWeb
