blob: 4a2b39bf029167930bd729c26d5dc4ad2b84ef5d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit git-r3 eutils cmake-utils
DESCRIPTION="i3-compatible Wayland window manager"
HOMEPAGE="http://swaywm.org/"
EGIT_REPO_URI="https://github.com/SirCmpwn/sway.git"
LICENSE="MIT"
SLOT="0"
KEYWORDS=""
IUSE="swaylock swaybg swaybar swaygrab swaymsg gdk-pixbuf zsh-completion wallpapers systemd"
RDEPEND="=dev-libs/wlc-9999[systemd=]
dev-libs/json-c
dev-libs/libpcre
dev-libs/libinput
x11-libs/libxkbcommon
dev-libs/wayland
x11-libs/pango
x11-libs/cairo
swaylock? ( virtual/pam )
gdk-pixbuf? ( x11-libs/gdk-pixbuf[jpeg] )"
DEPEND="${RDEPEND}
app-text/asciidoc"
src_prepare() {
default
# remove bad CFLAGS that upstream is trying to add
sed -i -e '/FLAGS.*-Werror/d' -e '/FLAGS.*-g/d' CMakeLists.txt || die
}
src_configure() {
local mycmakeargs=(
-Denable-swaybar=$(usex swaybar)
-Denable-swaybg=$(usex swaybg)
-Denable-swaygrab=$(usex swaygrab)
-Denable-swaylock=$(usex swaylock)
-Denable-swaymsg=$(usex swaymsg)
-Ddefault-wallpaper=$(usex wallpapers)
-Denable-gdk-pixbuf=$(usex gdk-pixbuf)
-Dzsh-completions=$(usex zsh-completion)
-DCMAKE_INSTALL_SYSCONFDIR="/etc"
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
use !systemd && fperms u+s /usr/bin/sway
}
pkg_postinst() {
if use swaygrab
then
optfeature "swaygrab screenshot support" media-gfx/imagemagick[png]
optfeature "swaygrab video capture support" virtual/ffmpeg
fi
}
|
GitWeb
