blob: 79831234c9906bca5bcfbd251a424d9b4dbedf32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..10} )
inherit distutils-r1
DESCRIPTION="Full featured redis cache backend for Django"
HOMEPAGE="https://github.com/jazzband/django-redis/"
SRC_URI="mirror://pypi/${PN:0:1}"/${PN}/${P}.tar.gz
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
>=dev-python/django-2.2[${PYTHON_USEDEP}]
>=dev-python/redis-py-3.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-db/redis
dev-python/lz4[${PYTHON_USEDEP}]
dev-python/msgpack[${PYTHON_USEDEP}]
dev-python/pytest-django[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
sed -e '/--cov/d' \
-e '/--no-cov/d' \
-e '/redis/s:,<4::' \
-i setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
cd tests || die
local setting_file settings=(
settings.sqlite
settings.sqlite_json
settings.sqlite_lz4
settings.sqlite_msgpack
settings.sqlite_sharding
settings.sqlite_zlib
# TODO: requires pyzstd
# settings.sqlite_zstd
)
for setting_file in "${settings[@]}"; do
einfo "Testing ${setting_file} configuration"
epytest "--ds=${setting_file}"
done
}
src_test() {
local redis_pid="${T}"/redis.pid
local redis_port=6379
local redis_test_config="
daemonize yes
pidfile ${redis_pid}
port ${redis_port}
bind 127.0.0.1
"
# Spawn Redis itself for testing purposes
einfo "Spawning Redis"
einfo "NOTE: Port ${redis_port} must be free"
"${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
# Run the tests
distutils-r1_src_test
# Clean up afterwards
kill "$(<"${redis_pid}")" || die
}
|
GitWeb