blob: f262e0114a2466d0beefd6d0e02cdad85c9f3020 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="A self-contained cryptographic library for Python"
HOMEPAGE="https://www.pycryptodome.org https://github.com/Legrandin/pycryptodome https://pypi.org/project/pycryptodome/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD-2 Unlicense"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 s390 sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE=""
RDEPEND="dev-libs/gmp:0
virtual/python-cffi[${PYTHON_USEDEP}]
!dev-python/pycrypto"
BDEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}/pycryptodome-3.9.4-parallel-make.patch"
)
distutils_enable_tests setup.py
python_prepare_all() {
# parallel make fixes
# Multiple targets were compiling the same file, setuptools doesn't
# understand this and you get race conditions where a file gets
# overwritten while it's linking. This makes the files look like separate
# files so this race won't happen
ln src/blowfish.c src/blowfish_eks.c || die
ln src/mont.c src/mont_math.c || die
distutils-r1_python_prepare_all
}
|
GitWeb
