dev-python/twython/twython-3.9.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1

DESCRIPTION="An easy way to access Twitter data with Python"
HOMEPAGE="https://github.com/ryanmcgrath/twython"
SRC_URI="
	https://github.com/ryanmcgrath/twython/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz"

SLOT="0"
LICENSE="MIT"
KEYWORDS="amd64 x86"

RDEPEND="
	>=dev-python/requests-2.1.0[${PYTHON_USEDEP}]
	>=dev-python/requests-oauthlib-0.4.0[${PYTHON_USEDEP}]"
BDEPEND="
	test? ( dev-python/responses[${PYTHON_USEDEP}] )"

distutils_enable_tests pytest

python_test() {
	local deselect=(
		# tests are largely unmaintained and outdated
		tests/test_core.py::TwythonAPITestCase::test_get_lastfunction_header_should_return_header
		tests/test_core.py::TwythonAPITestCase::test_request_should_handle_400_for_missing_auth_data
		tests/test_core.py::TwythonAPITestCase::test_request_should_handle_400_that_is_not_auth_related
		tests/test_core.py::TwythonAPITestCase::test_request_should_handle_401
		tests/test_core.py::TwythonAPITestCase::test_request_should_handle_rate_limit
	)
	epytest ${deselect[@]/#/--deselect }
}