blob: d6208fd4678af6c415300befa311abca213b9150 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby26 ruby27 ruby30"
RUBY_FAKEGEM_EXTRADOC="README.md AUTHORS CONTRIBUTERS"
RUBY_FAKEGEM_EXTRAINSTALL="data"
inherit ruby-fakegem
DESCRIPTION="Yet-another-markdown-parser but fast, pure Ruby, using strict syntax definition"
HOMEPAGE="https://kramdown.gettalong.org/"
LICENSE="MIT"
SLOT="$(ver_cut 1)"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~s390 ~sparc ~x86"
IUSE="latex"
LATEX_DEPS="latex? ( dev-texlive/texlive-latex dev-texlive/texlive-latexextra )"
RDEPEND+=" ${LATEX_DEPS}"
DEPEND+=" test? (
${LATEX_DEPS}
>=app-text/htmltidy-5.0.0
)"
ruby_add_rdepend "
dev-ruby/rexml
>=dev-ruby/rouge-3.26.0:2
>=dev-ruby/stringex-1.5.1
!!<dev-ruby/kramdown-1.17.0-r2:0"
ruby_add_bdepend "doc? ( dev-ruby/rdoc )
test? ( >=dev-ruby/minitest-5.0 )"
all_ruby_prepare() {
if ! use latex; then
# Remove latex tests. They will fail gracefully when latex isn't
# present at all, but not when components are missing (most
# notable ucs.sty).
sed -i -e '/latex -v/,/^ end/ s:^:#:' test/test_files.rb || die
fi
}
each_ruby_test() {
${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
}
all_ruby_install() {
all_fakegem_install
doman man/man1/kramdown.1
}
|
GitWeb
