blob: ed2882a05f8efaefe3174ef70e0affdc185eec9d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit user
DESCRIPTION="An IRC server written from scratch"
HOMEPAGE="https://ngircd.barton.de/"
SRC_URI="https://arthur.barton.de/pub/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86 ~x64-macos"
IUSE="debug gnutls iconv ident ipv6 libressl pam ssl tcpd test zlib"
RDEPEND="
iconv? ( virtual/libiconv )
ident? ( net-libs/libident )
pam? ( virtual/pam )
ssl? (
gnutls? ( net-libs/gnutls:= )
!gnutls? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
)
tcpd? ( sys-apps/tcp-wrappers )
zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
>=sys-apps/sed-4
test? (
dev-tcltk/expect
net-misc/netkit-telnetd
)
"
# Testsuite fails server-login-test
RESTRICT="test"
src_prepare() {
default
if ! use prefix; then
sed -i \
-e "s:;ServerUID = 65534:ServerUID = ngircd:" \
-e "s:;ServerGID = 65534:ServerGID = nogroup:" \
doc/sample-ngircd.conf.tmpl || die
fi
}
src_configure() {
local myconf=(
--sysconfdir="${EPREFIX}"/etc/"${PN}"
$(use_enable debug sniffer)
$(use_enable debug)
$(use_enable ipv6)
$(use_with iconv)
$(use_with ident)
$(use_with pam)
$(use_with tcpd tcp-wrappers)
$(use_with zlib)
)
if use ssl; then
myconf+=(
$(use_with !gnutls openssl)
$(use_with gnutls)
)
else
myconf+=(
--without-gnutls
--without-openssl
)
fi
econf "${myconf[@]}"
}
src_install() {
default
newinitd "${FILESDIR}"/ngircd.init-r1.d ngircd
}
pkg_postinst() {
if ! use prefix; then
enewuser ngircd
chown ngircd "${EROOT%/}"/etc/ngircd/ngircd.conf || die
fi
}
|
GitWeb