blob: 7715570cbd9216a64ef4d0e8d1c8efdd3a5370e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit systemd user eutils readme.gentoo-r1
DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
HOMEPAGE="http://v6web.litech.org/radvd/"
SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~sparc ~x86"
IUSE="kernel_FreeBSD selinux test"
CDEPEND="dev-libs/libdaemon"
DEPEND="${CDEPEND}
sys-devel/bison
sys-devel/flex
virtual/pkgconfig
test? ( dev-libs/check )"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-radvd )
"
DOCS=( CHANGES README TODO radvd.conf.example )
PATCHES=(
"${FILESDIR}"/${P}-nd_opt_6co.patch
)
pkg_setup() {
enewgroup radvd
enewuser radvd -1 -1 /dev/null radvd
}
src_configure() {
econf --with-pidfile=/run/radvd/radvd.pid \
--disable-silent-rules \
--with-systemdsystemunitdir=no \
$(use_with test check)
}
src_install() {
default
insinto /usr/share/doc/${PF}/html
doins INTRO.html
newinitd "${FILESDIR}"/${PN}-2.15.init ${PN}
newconfd "${FILESDIR}"/${PN}.conf ${PN}
systemd_dounit "${FILESDIR}"/${PN}.service
if use kernel_FreeBSD ; then
sed -i -e \
's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
"${D}"/etc/init.d/${PN} || die
fi
readme.gentoo_create_doc
}
DISABLE_AUTOFORMATTING=1
DOC_CONTENTS="Please create a configuration file ${ROOT}etc/radvd.conf.
See ${ROOT}usr/share/doc/${PF} for an example.
grsecurity users should allow a specific group to read /proc
and add the radvd user to that group, otherwise radvd may
segfault on startup."
|
GitWeb
