blob: 2b6d597e8e814994496eef3e02f253933a87968e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VALA_USE_DEPEND="vapigen"
PYTHON_COMPAT=( python3_{8..11} )
inherit desktop meson optfeature python-any-r1 readme.gentoo-r1 vala xdg
DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI"
HOMEPAGE="https://www.spice-space.org https://cgit.freedesktop.org/spice/spice-gtk/"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://anongit.freedesktop.org/git/spice/spice-gtk.git"
inherit git-r3
SPICE_PROTOCOL_VER=9999
else
SRC_URI="https://www.spice-space.org/download/gtk/${P}.tar.xz"
KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
SPICE_PROTOCOL_VER=0.14.3
fi
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="+gtk3 +introspection lz4 mjpeg policykit sasl smartcard usbredir vala wayland webdav"
# TODO:
# * check if sys-freebsd/freebsd-lib (from virtual/acl) provides acl/libacl.h
# * use external pnp.ids as soon as that means not pulling in gnome-desktop
RDEPEND="
>=dev-libs/glib-2.46:2
dev-libs/json-glib:0=
media-libs/gst-plugins-base:1.0
media-libs/gst-plugins-good:1.0
media-libs/gstreamer:1.0[introspection?]
media-libs/opus
media-libs/libjpeg-turbo:=
sys-libs/zlib
>=x11-libs/cairo-1.2
>=x11-libs/pixman-0.17.7
x11-libs/libX11
gtk3? ( x11-libs/gtk+:3[introspection?] )
introspection? ( dev-libs/gobject-introspection )
dev-libs/openssl:=
lz4? ( app-arch/lz4 )
sasl? ( dev-libs/cyrus-sasl )
smartcard? ( app-emulation/qemu[smartcard] )
usbredir? (
sys-apps/hwdata
>=sys-apps/usbredir-0.4.2
virtual/acl
virtual/libusb:1
policykit? (
>=sys-auth/polkit-0.110-r1
)
)
webdav? (
net-libs/phodav:2.0
>=net-libs/libsoup-2.49.91:2.4
)
"
# TODO: spice-gtk has an automagic dependency on media-libs/libva without a
# configure knob. The package is relatively lightweight so we just depend
# on it unconditionally for now. It would be cleaner to transform this into
# a USE="vaapi" conditional and patch the buildsystem...
RDEPEND="${RDEPEND}
amd64? ( media-libs/libva:= )
arm64? ( media-libs/libva:= )
x86? ( media-libs/libva:= )
"
DEPEND="${RDEPEND}
>=app-emulation/spice-protocol-${SPICE_PROTOCOL_VER}"
BDEPEND="
dev-perl/Text-CSV
dev-util/glib-utils
>=sys-devel/gettext-0.17
virtual/pkgconfig
vala? ( $(vala_depend) )
$(python_gen_any_dep '
dev-python/six[${PYTHON_USEDEP}]
dev-python/pyparsing[${PYTHON_USEDEP}]
')
"
python_check_deps() {
python_has_version "dev-python/six[${PYTHON_USEDEP}]" &&
python_has_version "dev-python/pyparsing[${PYTHON_USEDEP}]"
}
src_prepare() {
default
use vala && vala_setup
}
src_configure() {
local emesonargs=(
$(meson_feature gtk3 gtk)
$(meson_feature introspection)
$(meson_use mjpeg builtin-mjpeg)
$(meson_feature policykit polkit)
$(meson_feature lz4)
$(meson_feature sasl)
$(meson_feature smartcard)
$(meson_feature usbredir)
$(meson_feature vala vapi)
$(meson_feature webdav)
$(meson_feature wayland wayland-protocols)
)
if use elibc_musl; then
emesonargs+=(
-Dcoroutine=gthread
)
fi
if use usbredir; then
emesonargs+=(
-Dusb-acl-helper-dir=/usr/libexec
-Dusb-ids-path="${EPREFIX}"/usr/share/hwdata/usb.ids
)
fi
meson_src_configure
}
src_install() {
meson_src_install
if use usbredir && use policykit; then
# bug #775554 (and bug #851657)
fowners root:root /usr/libexec/spice-client-glib-usb-acl-helper
fperms 4755 /usr/libexec/spice-client-glib-usb-acl-helper
fi
make_desktop_entry spicy Spicy "utilities-terminal" "Network;RemoteAccess;"
readme.gentoo_create_doc
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "Sound support (via pulseaudio)" media-plugins/gst-plugins-pulse
}
|
GitWeb