blob: 4a6c7e575ec8795bd383ca5f72b6152725f56795 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit bash-completion-r1 distutils-r1 optfeature
DESCRIPTION="Download videos from YouTube.com (and more sites...)"
HOMEPAGE="https://youtube-dl.org/"
SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
S="${WORKDIR}/${PN}"
LICENSE="Unlicense"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ~hppa ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
IUSE="+yt-dlp"
# tests need deprecated nose, and given upstream is still refusing to make new
# releases or modernize anything (wants to support old python more) it will
# likely be last rited along with any revdeps that still can't use yt-dlp
RESTRICT="test"
RDEPEND="
dev-python/pycryptodome[${PYTHON_USEDEP}]
yt-dlp? ( >=net-misc/yt-dlp-2022.2.4-r1 )
!yt-dlp? ( !net-misc/yt-dlp )"
#distutils_enable_tests nose
python_prepare_all() {
distutils-r1_python_prepare_all
sed -i '/flake8/d' Makefile || die
}
python_test() {
emake offlinetest
}
python_install_all() {
dodoc AUTHORS ChangeLog README.md docs/supportedsites.md
doman youtube-dl.1
newbashcomp youtube-dl.bash-completion youtube-dl
insinto /usr/share/zsh/site-functions
newins youtube-dl.zsh _youtube-dl
insinto /usr/share/fish/vendor_completions.d
doins youtube-dl.fish
rm -r "${ED}"/usr/{etc,share/doc/youtube_dl} || die
# keep man pages / completions either way given they are useful
# for yt-dlp's compatibility wrapper which tries to mimic options
use !yt-dlp || rm -r "${ED}"/usr/{lib/python-exec,bin} || die
}
pkg_postinst() {
optfeature "converting and merging tracks on some sites" media-video/ffmpeg
optfeature "embedding metadata thumbnails in MP4/M4A files" media-video/atomicparsley
optfeature "downloading videos streamed via RTMP" media-video/rtmpdump
optfeature "downloading videos streamed via MMS/RTSP" media-video/mplayer media-video/mpv
ewarn "Note that it is preferable to use net-misc/yt-dlp over youtube-dl for"
ewarn "latest features and site support. youtube-dl is only kept maintained for"
ewarn "compatibility with older software (notably its python module, yt-dlp has"
ewarn "a 'bin/youtube-dl' compatibility wrapper but not for the module)."
if use yt-dlp; then
ewarn
ewarn "USE=yt-dlp is enabled, so said compatibility wrapper will be used. Man pages"
ewarn "and completions for youtube-dl were still installed but may have slight usage"
ewarn "differences and does not read the same configuration files. It is recommended"
ewarn "to use the yt-dlp command directly instead."
fi
}
|
GitWeb