sci-biology/eugene/eugene-4.1d.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools

DESCRIPTION="Prokaryotic and Eukaryotic gene predictor"
HOMEPAGE="http://eugene.toulouse.inra.fr/"
SRC_URI="https://mulcyber.toulouse.inra.fr/frs/download.php/1359/${P}.tar.gz"

LICENSE="Artistic"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

DEPEND="
	media-libs/gd[png]
	media-libs/libpng:0=
	"
RDEPEND="${DEPEND}"

RESTRICT="test"

PATCHES=(
	# https://mulcyber.toulouse.inra.fr/tracker/index.php?func=detail&aid=1170
	"${FILESDIR}"/${PN}-3.6-overflow.patch
	"${FILESDIR}"/${PN}-3.6-plugins.patch
	"${FILESDIR}"/${PN}-4.1-format-security.patch
	"${FILESDIR}"/${PN}-4.1d-fix-c++14.patch
	"${FILESDIR}"/${PN}-4.1d-Wformat.patch
)

src_prepare() {
	default
	sed \
		-e '/SUBDIRS/ s/doc//' \
		-e '/INSTALL.*doc/ s/\(.*\)//' \
		-i Makefile.am || die
	eautoreconf
}