blob: 6370647900833f39850eef56ed1b5050e25eca88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_PV=${PV/_/}
DESCRIPTION="Geometry engine library for Geographic Information Systems"
HOMEPAGE="http://trac.osgeo.org/geos/"
SRC_URI="http://download.osgeo.org/geos/${PN}-${MY_PV}.tar.bz2"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ia64 ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="doc ruby static-libs"
BDEPEND="
doc? ( app-doc/doxygen )
ruby? ( dev-lang/swig:0 )
"
RDEPEND="
ruby? ( dev-lang/ruby:* )
"
DEPEND="${RDEPEND}"
RESTRICT="test"
S="${WORKDIR}"/${PN}-${MY_PV}
src_prepare() {
default
echo "#!${EPREFIX}/bin/bash" > py-compile
}
src_configure() {
local myeconfargs=(
--disable-python
$(use_enable ruby)
$(use_enable static-libs static)
)
use arm && myeconfargs+=( --disable-inline ) # bug 709368
econf "${myeconfargs[@]}"
}
src_compile() {
default
use doc && emake -C doc doxygen-html
}
src_install() {
use doc && HTML_DOCS=( doc/doxygen_docs/html/. )
default
find "${D}" -name '*.la' -delete || die
}
|
GitWeb
