blob: 953cc42fcc2d0cd1e3e7a2afcbc0f2a9f59b6173 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="Library that allows non-privileged apps to write utmp (login) info"
HOMEPAGE="https://altlinux.org/index.php?module=sisyphus&package=libutempter"
SRC_URI="ftp://ftp.altlinux.org/pub/people/ldv/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
IUSE="static-libs"
RDEPEND="
!sys-apps/utempter
acct-group/utmp
"
src_prepare() {
default
local args=(
-e "/^libdir /s:/usr/lib:${EPREFIX}/usr/$(get_libdir):"
-e '/^libexecdir /s:=.*:= $(libdir)/misc:'
-e '/^CFLAGS = $(RPM_OPT_FLAGS)/d'
-e 's:-Wl,-stats::'
-e "/^includedir /s:/usr/include:${EPREFIX}/usr/include:"
-e "/^mandir /s:=.*:= ${EPREFIX}/usr/share/man:"
)
if ! use static-libs ; then
args+=(
-e '/^STATICLIB/d'
-e '/INSTALL.*STATICLIB/d'
)
fi
sed -i "${args[@]}" Makefile || die
}
src_configure() {
tc-export AR CC
}
src_compile() {
emake LDLIBS="${LIBS}"
}
src_install() {
default
if ! use prefix ; then
fowners root:utmp /usr/$(get_libdir)/misc/utempter/utempter
fperms 2755 /usr/$(get_libdir)/misc/utempter/utempter
fi
dodir /usr/sbin
dosym ../$(get_libdir)/misc/utempter/utempter /usr/sbin/utempter
}
pkg_postinst() {
local path
for path in "${EROOT}"/var/log/{w,u}tmp; do
chown root:utmp "${path}"
chmod 664 "${path}"
done
}
|
GitWeb
