blob: 2edd3ca69fd17ff8909503b927f971738b46ca29 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
inherit cmake-multilib git-r3 llvm multiprocessing python-any-r1
DESCRIPTION="C++ runtime stack unwinder from LLVM"
HOMEPAGE="https://github.com/llvm-mirror/libunwind"
SRC_URI=""
EGIT_REPO_URI="https://github.com/llvm/llvm-project.git"
S=${WORKDIR}/${P}/libunwind
LICENSE="Apache-2.0-with-LLVM-exceptions || ( UoI-NCSA MIT )"
SLOT="0"
KEYWORDS=""
IUSE="debug +static-libs test"
RESTRICT="!test? ( test )"
RDEPEND="!sys-libs/libunwind"
# llvm-6 for new lit options
DEPEND="
>=sys-devel/llvm-6"
BDEPEND="
test? ( >=sys-devel/clang-3.9.0
$(python_gen_any_dep 'dev-python/lit[${PYTHON_USEDEP}]') )"
# least intrusive of all
CMAKE_BUILD_TYPE=RelWithDebInfo
src_unpack() {
local dirs=( libunwind )
use test && dirs+=( libcxx{,abi} )
git-r3_fetch
git-r3_checkout '' '' '' "${dirs[@]}"
}
python_check_deps() {
has_version "dev-python/lit[${PYTHON_USEDEP}]"
}
pkg_setup() {
use test && python-any-r1_pkg_setup
}
multilib_src_configure() {
local libdir=$(get_libdir)
local mycmakeargs=(
-DLLVM_LIBDIR_SUFFIX=${libdir#lib}
-DLIBUNWIND_ENABLE_ASSERTIONS=$(usex debug)
-DLIBUNWIND_ENABLE_STATIC=$(usex static-libs)
-DLLVM_INCLUDE_TESTS=$(usex test)
# support non-native unwinding; given it's small enough,
# enable it unconditionally
-DLIBUNWIND_ENABLE_CROSS_UNWINDING=ON
)
if use test; then
local clang_path=$(type -P "${CHOST:+${CHOST}-}clang" 2>/dev/null)
local jobs=${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}
[[ -n ${clang_path} ]] || die "Unable to find ${CHOST}-clang for tests"
mycmakeargs+=(
-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-DLLVM_LIT_ARGS="-vv;-j;${jobs};--param=cxx_under_test=${clang_path}"
-DLIBUNWIND_LIBCXX_PATH="${WORKDIR}/${P}/libcxx"
)
fi
cmake-utils_src_configure
}
build_libcxxabi() {
local -x LDFLAGS="${LDFLAGS} -L${BUILD_DIR}/$(get_libdir)"
local CMAKE_USE_DIR=${WORKDIR}/${P}/libcxxabi
local BUILD_DIR=${BUILD_DIR}/libcxxabi
local mycmakeargs=(
-DLIBCXXABI_LIBDIR_SUFFIX=
-DLIBCXXABI_ENABLE_SHARED=OFF
-DLIBCXXABI_ENABLE_STATIC=ONF
-DLIBCXXABI_USE_LLVM_UNWINDER=ON
-DLIBCXXABI_INCLUDE_TESTS=OFF
-DLIBCXXABI_LIBCXX_INCLUDES="${WORKDIR}/${P}"/libcxx/include
-DLIBCXXABI_LIBUNWIND_INCLUDES="${S}"/include
)
cmake-utils_src_configure
cmake-utils_src_compile
}
build_libcxx() {
local -x LDFLAGS="${LDFLAGS} -L${BUILD_DIR}/libcxxabi/lib -L${BUILD_DIR}/$(get_libdir)"
local CMAKE_USE_DIR=${WORKDIR}/${P}/libcxx
local BUILD_DIR=${BUILD_DIR}/libcxx
local mycmakeargs=(
-DLIBCXX_LIBDIR_SUFFIX=
-DLIBCXX_ENABLE_SHARED=OFF
-DLIBCXX_ENABLE_STATIC=ON
-DLIBCXX_ENABLE_EXPERIMENTAL_LIBRARY=OFF
-DLIBCXXABI_USE_LLVM_UNWINDER=ON
-DLIBCXX_CXX_ABI=libcxxabi
-DLIBCXX_CXX_ABI_INCLUDE_PATHS="${WORKDIR}/${P}"/libcxxabi/include
-DLIBCXX_ENABLE_ABI_LINKER_SCRIPT=OFF
-DLIBCXX_HAS_MUSL_LIBC=$(usex elibc_musl)
-DLIBCXX_HAS_GCC_S_LIB=OFF
-DLIBCXX_INCLUDE_TESTS=OFF
)
cmake-utils_src_configure
cmake-utils_src_compile
}
multilib_src_test() {
# build local copies of libc++ & libc++abi for testing to avoid
# circular deps
build_libcxxabi
build_libcxx
mv "${BUILD_DIR}"/libcxx*/lib/libc++* "${BUILD_DIR}/$(get_libdir)/" || die
local -x LIT_PRESERVES_TMP=1
cmake-utils_src_make check-unwind
}
multilib_src_install() {
cmake-utils_src_install
# install headers like sys-libs/libunwind
doheader "${S}"/include/*.h
}
|
GitWeb