blob: a9bd005eae5fd03aa0d1e9788481b4764ba49c1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit autotools ltprune
DESCRIPTION="GObject-based XIM protocol library"
HOMEPAGE="https://tagoh.bitbucket.io/libgxim"
SRC_URI="https://bitbucket.org/tagoh/${PN}/downloads/${P}.tar.bz2"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="static-libs test"
RDEPEND="dev-libs/dbus-glib
dev-libs/glib:2
sys-apps/dbus
virtual/libintl
x11-libs/gtk+:2"
DEPEND="${RDEPEND}
dev-lang/ruby
dev-util/intltool
sys-devel/autoconf-archive
sys-devel/gettext
virtual/pkgconfig
test? ( dev-libs/check )"
AT_M4DIR="m4macros"
src_prepare() {
sed -i \
-e "/PKG_CHECK_MODULES/s/\(check\)/$(usex test '\1' _)/" \
-e "/^GNOME_/d" \
-e "/^CFLAGS/s/\$WARN_CFLAGS/-Wall -Wmissing-prototypes/" \
configure.ac
sed -i "/^ACLOCAL_AMFLAGS/,/^$/d" Makefile.am
default
eautoreconf
}
src_configure() {
econf $(use_enable static-libs static)
}
src_install() {
default
prune_libtool_files
}
|
GitWeb
