add tp-glib scm

Signed-off-by: Marc-Antoine Perennou <Marc-Antoine@Perennou.com>

2 files changed, 68 insertions, 0 deletions

diff --git a/net-libs/telepathy-glib/Manifest b/net-libs/telepathy-glib/Manifest
new file mode 100644
index 00000000..21e62bd4
--- /dev/null
+++ b/net-libs/telepathy-glib/Manifest
@@ -0,0 +1 @@
+EBUILD telepathy-glib-9999.ebuild 1536 RMD160 6ebd9586a0b0da9da5b3e5de85e208833b214a44 SHA1 46e9aabd852b5623ad4775f76873e8686f8112a8 SHA256 ae3b4dac2eae9a5bffe19e3e8d41700724e274ab9350807108baafd9a8cd4a72
diff --git a/net-libs/telepathy-glib/telepathy-glib-9999.ebuild b/net-libs/telepathy-glib/telepathy-glib-9999.ebuild
new file mode 100644
index 00000000..7711b0d7
--- /dev/null
+++ b/net-libs/telepathy-glib/telepathy-glib-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.5"
+
+inherit git-2 autotools python virtualx
+
+DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol."
+HOMEPAGE="http://telepathy.freedesktop.org"
+SRC_URI=""
+EGIT_REPO_URI="git://anongit.freedesktop.org/telepathy/telepathy-glib"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug +introspection +vala"
+
+RDEPEND=">=dev-libs/glib-2.28:2
+	>=dev-libs/dbus-glib-0.82
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
+	vala? (
+		dev-lang/vala:0.14[vapigen]
+		>=dev-libs/gobject-introspection-0.9.6 )"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc
+	dev-libs/libxslt
+	>=dev-util/pkgconfig-0.21"
+
+src_prepare() {
+	python_convert_shebangs -r 2 examples tests tools
+	gtkdocize
+	eautoreconf
+	default_src_prepare
+}
+
+src_configure() {
+	local myconf
+
+	if use vala; then
+		myconf="--enable-introspection
+			VALAC=$(type -p valac-0.14)
+			VAPIGEN=$(type -p vapigen-0.14)"
+	fi
+
+	econf --disable-static \
+		PYTHON=$(PYTHON -2 -a) \
+		$(use_enable debug backtrace) \
+		$(use_enable debug handle-leak-debug) \
+		$(use_enable debug debug-cache) \
+		$(use_enable introspection) \
+		$(use_enable vala vala-bindings) \
+		${myconf}
+}
+
+src_test() {
+	# Needs dbus for tests (auto-launched)
+	Xemake -j1 check || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"
+
+	find "${ED}" -name '*.la' -exec rm -f '{}' + || die
+}