blob: 774df3842ed2bdad22d96a2e5582485b34cf82ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id: 15cfd8363e83463521767fb4d10340388ee47b7f $
EAPI=5
inherit eutils toolchain-funcs flag-o-matic
DESCRIPTION="standard informational utilities and process-handling tools"
HOMEPAGE="http://procps-ng.sourceforge.net/ https://gitlab.com/procps-ng/procps"
SRC_URI="mirror://sourceforge/${PN}-ng/${PN}-ng-${PV}.tar.xz
https://gitlab.com/procps-ng/procps/commit/b2f49b105d23c833d733bf7dfb99cb98e4cae383.patch -> ${PN}-3.3.11-remove_Unix98_output_limits.patch"
LICENSE="GPL-2"
SLOT="0/5" # libprocps.so
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~ia64-linux ~x86-linux"
IUSE="+kill +ncurses modern-top nls selinux static-libs systemd test unicode"
RDEPEND="ncurses? ( >=sys-libs/ncurses-5.7-r7:=[unicode?] )
selinux? ( sys-libs/libselinux )
systemd? ( >=sys-apps/systemd-209 )"
DEPEND="${RDEPEND}
ncurses? ( virtual/pkgconfig )
systemd? ( virtual/pkgconfig )
test? ( dev-util/dejagnu )"
RDEPEND+="
kill? (
!sys-apps/coreutils[kill]
!sys-apps/util-linux[kill]
)
!<sys-apps/sysvinit-2.88-r6"
S="${WORKDIR}/${PN}-ng-${PV}"
PATCHES=(
"${FILESDIR}"/${PN}-3.3.8-kill-neg-pid.patch # http://crbug.com/255209
"${FILESDIR}"/${PN}-3.3.11-sysctl-manpage.patch # 565304
"${FILESDIR}"/${PN}-3.3.12-proc-tests.patch #583036
# Upstream fixes
"${FILESDIR}"/${P}-strtod_nol_err.patch
)
src_prepare() {
epatch "${PATCHES[@]}"
epatch_user
}
src_configure() {
# http://www.freelists.org/post/procps/PATCH-enable-transparent-large-file-support
append-lfs-flags #471102
econf \
--docdir='$(datarootdir)'/doc/${PF} \
$(use_enable kill) \
$(use_enable modern-top) \
$(use_with ncurses) \
$(use_enable nls) \
$(use_enable selinux libselinux) \
$(use_enable static-libs static) \
$(use_with systemd) \
$(use_enable unicode watch8bit)
}
src_test() {
emake check </dev/null #461302
}
src_install() {
local binary
default
#dodoc sysctl.conf
dodir /bin
for binary in pidof ps; do
mv "${ED}"/usr/bin/"${binary}" "${ED}"/bin/ || die
done
if use kill; then
mv "${ED}"/usr/bin/kill "${ED}"/bin/ || die
fi
dodir /sbin
for binary in sysctl; do
mv "${ED}"/usr/sbin/"${binary}" "${ED}"/sbin/ || die
done
gen_usr_ldscript -a procps
prune_libtool_files
}
|
GitWeb